# Maintainer: David P. <megver83@parabola.nu>
# Maintainer: Omar Vega Ramos <ovruni@gnu.org.pe>
# Maintainer (Arch): Jan Alexander Steffens (heftig) <jan.steffens@gmail.com>
# Contributor: Ionut Biru <ibiru@archlinux.org>

pkgname=accountsservice-elogind
_pkgname=${pkgname/-elogind}
pkgver=0.6.47
pkgrel=1
pkgdesc="D-Bus interface for user account query and manipulation"
url="https://www.freedesktop.org/software/accountsservice/"
arch=(x86_64 i686 armv7h)
license=(GPL3)
depends=(glib2 polkit-elogind)
makedepends=(intltool gtk-doc gobject-introspection git)
provides=($_pkgname)
conflicts=($_pkgname)
_commit=883b9101ec21e4b7ad0522c9dcc1a87465a750cd  # tags/0.6.47^0
source=("git+https://anongit.freedesktop.org/git/accountsservice#commit=$_commit")
sha256sums=('SKIP')

pkgver() {
  cd $_pkgname
  git describe --tags | sed 's/-/+/g'
}


prepare() {
  cd $_pkgname
  NOCONFIGURE=1 ./autogen.sh
}

build() {
  cd $_pkgname
  ./configure \
    --prefix=/usr \
    --sysconfdir=/etc \
    --localstatedir=/var \
    --libexecdir=/usr/lib \
    --disable-static \
    --enable-gtk-doc \
    --enable-elogind=yes \
    --enable-systemd=no \
    --with-systemdsystemunitdir=no
  make
}

package() {
  cd $_pkgname
  make DESTDIR="$pkgdir" install
}

# vim:set ts=2 sw=2 et: