# Maintainer (AUR): e5ten <e5ten.arch@gmail.com>
# Contributor (AUR): Sven-Hendrik Haase <sh@lutzhaase.com>
# Contributor (AUR): M0Rf30
# Contributor (AUR): Samsagax <samsagax@gmail.com>
# Contributor (Hyperbola): André Silva <emulatorman@hyperbola.info>
# Contributor (Hyperbola): Márcio Silva <coadde@hyperbola.info>
# Maintainer: Omar Vega Ramos <ovruni@gnu.org.pe>

_basekernel=4.19.97-1

pkgname=bbswitch-lts
pkgver=0.8
pkgrel=47
pkgrel+=.parabola1.basekernel${_basekernel%-*}
pkgdesc="Kernel module allowing to switch dedicated graphics card on Optimus laptops"
pkgdesc+=" (built for the linux-libre-lts kernel package)"
arch=('x86_64')
arch+=('i686')
url="http://github.com/Bumblebee-Project/bbswitch"
license=('GPL')
makedepends=(linux-libre-lts-headers=${_basekernel%-*} git libelf)
source=("${pkgname%-*}-$pkgver.tar.gz::https://github.com/Bumblebee-Project/bbswitch/archive/v${pkgver}.tar.gz")
sha256sums=('76cabd3f734fb4fe6ebfe3ec9814138d0d6f47d47238521ecbd6a986b60d1477')

build() {
  cd ${pkgname%-*}-${pkgver}
  make KDIR=/usr/src/linux-libre-lts
}

package() {
  depends=(linux-libre-lts=${_basekernel%-*})

  cd ${pkgname%-*}-${pkgver}
  _extradir="/usr/lib/modules/$(</usr/src/linux-libre-lts/version)/extramodules"
  install -Dt "${pkgdir}${_extradir}" -m644 *.ko
  find "${pkgdir}" -name '*.ko' -exec xz {} +
}