# Maintainer (AUR): Cristian Baldi crisbal <bld.cris.96@gmail.com>
# Maintainer: Luke Shumaker <lukeshu@sbcglobal.net>

pkgname=byaccj
pkgver=1.15
pkgrel=1

pkgdesc="An extension of the Berkeley YACC-compatible parser generator."
url="http://byaccj.sourceforge.net/"
license=("custom: public domain")

arch=('i686' 'x86_64')
source=(http://downloads.sourceforge.net/project/byaccj/${pkgname}/${pkgver}/${pkgname}${pkgver}_src.tar.gz
        http://metadata.ftp-master.debian.org/changelogs/main/b/byacc-j/byacc-j_${pkgver}-1_copyright
        ldflags.patch)
md5sums=('5ee9959af35f245ac2c4355f85fdf351'
         'cc9e2ed821e7f2e5ef8f2be0fdc97b46'
         '76fd678b41d614497cf77c6dba5de63e')

prepare() {
  cd "$srcdir"/$pkgname$pkgver
  patch -Np1 -i ../ldflags.patch
}

build() {
  cd "$srcdir"/$pkgname$pkgver
  make -C src linux CFLAGS="$CFLAGS" LDFLAGS="$LDFLAGS"
}

package() {
  cd "$srcdir"/$pkgname$pkgver
  install -Dm755 src/yacc.linux "$pkgdir"/usr/bin/byaccj
  install -Dm644 src/yacc.1     "$pkgdir"/usr/share/man/man1/byaccj.1
  install -d                    "$pkgdir"/usr/share/doc/$pkgname
  install  -m644 docs/*      -t "$pkgdir"/usr/share/doc/$pkgname
  install -Dm644 ../byacc-j_$pkgver-1_copyright "$pkgdir"/usr/share/licenses/$pkgname/copyright
}