# $Id$
# Maintainer: tobias [tobias.archlinux.org]
# Contributor: tobias [tobias.justdreams.de]
# Maintainer (Parabola): Márcio Silva <coadde@lavabit.com>

pkgname=cinepaint-lts
pkgver=1.0
pkgrel=1
pkgdesc='Sophisticated graphics manipulation programm supporting > 8bit pictures'
arch=(i686 x86_64 mips64el)
license=(LGPL GPL MIT)
url=http://www.${pkgname%-lts}.org
depends=(gtk2 openexr lcms libxpm fltk ftgl libxxf86vm)
makedepends=(python2 gutenprint)
optdepends=(
  'python2: for python plug-ins'
  'gutenprint: for print plug-ins'
  'ghostscript: for pdf plug-ins'
)
conflicts=(${pkgname%-lts})
provides=(${pkgname%-lts})
options=(!libtool)
install=${pkgname%-lts}.install
source=(
  http://sourceforge.net/projects/${pkgname%-lts}/files/CinePaint/${pkgname%-lts}-$pkgver.tgz
  LICENSE
  ${pkgname%-lts}-libpng15.patch
)
md5sums=(
  7dfdb005d246578392ac9bd500534804
  169085743f667c250ea2e4022efecf5f
  6d3f65b72e0f1569a9efe1bcab1b8124
)

build() {
  cd $srcdir/${pkgname%-lts}

  rm config.{sub,guess}
  ln -s /usr/share/automake-1.12/config.sub   config.sub
  ln -s /usr/share/automake-1.12/config.guess config.guess

  patch -p1 -i ../${pkgname%-lts}-libpng15.patch
  find plug-ins/pygimp -type f -exec sed -i 's#env python#env python2#' {} +
  sed -i 's|$(LDFLAGS) -o|$(LDFLAGS) $(GTK_LIBS) -o|' lib/Makefile.in
  sed -i -e '1 s/^/#include <unistd.h>\n/' plug-ins/icc_examin/icc_examin/icc_modell_beobachter.cpp

  sh autogen.sh
  LIBS+="-lstdc++ -lm -lX11" ./configure --prefix=/usr --libdir=/usr/lib --mandir=/usr/share/man \
    --enable-gtk2 --enable-pygimp --with-python=/usr/bin/python2
  sed -i 's/-Wl,,/-Wl,/' lib/fl_i18n/Makefile plug-ins/bracketing_to_hdr/Makefile \
    plug-ins/collect/Makefile plug-ins/icc_examin/icc_examin/Makefile plug-ins/pdf/Makefile
  make
}

package() {
  cd $srcdir/${pkgname%-lts}
  make DESTDIR=$pkgdir install
  sed -i -e "s|-I$srcdir/${pkgname%-lts}||" -e "s|-I$srcdir/${pkgname%-lts}/lib||" -e "/lib${pkgname%-lts}.la/d" \
    -e "s|${srcdir}/${pkgname%-lts}/lib/.libs/\$dlname||" $pkgdir/usr/bin/${pkgname%-lts}tool
  sed -i "s/${pkgname%-lts}.png/${pkgname%-lts}/" $pkgdir/usr/share/applications/${pkgname%-lts}.desktop
  install -D -m644 $srcdir/LICENSE $pkgdir/usr/share/licenses/$pkgname/LICENSE
}