# Maintainer: Luke Shumaker <lukeshu@sbcglobal.net>
# Maintainer (AUR): Buce <dmbuce@gmail.com>
# Contributor: Danie Roux <accounts@danieroux.com>
# Contributor: Diogo Leal <estranho@diogoleal.com>

pkgname=etckeeper
pkgver=1.4
pkgdesc="Collection of tools to let /etc be stored in a git, hg, bzr or darcs repository."
url="http://joeyh.name/code/etckeeper/"
license=('GPL2')

pkgrel=1
arch=('any')
depends=('inetutils' 'python2')
makedepends=('bzr') # bzr must be there at compile time to have bzr support
optdepends=('git' 'hg' 'bzr' 'darcs')
backup=(etc/etckeeper/etckeeper.conf)
source=("libre://$pkgname-$pkgver.tar.gz" $pkgname-pacman.patch $pkgname-archlinux.conf)

mksource=("$pkgname-$pkgver::git://git.kitenet.net/$pkgname#tag=${pkgver}")
mkmd5sums=('SKIP')

build() {
  cd "${srcdir}/${pkgname}-${pkgver}"

  # add pacman support to `list-installed`
  patch -p0 -i "${srcdir}/${pkgname}-pacman.patch"

  # use python2
  sed -i 's@^#!/usr/bin/python$@&2@' etckeeper-bzr/__init__.py
  make CONFFILE="${srcdir}/${pkgname}-archlinux.conf" build
}

package() {
  cd "${srcdir}/${pkgname}-${pkgver}"

  make CONFFILE="${srcdir}/${pkgname}-archlinux.conf" DESTDIR="$pkgdir" install
}

md5sums=('74be692fdb2d3352324e9332a270635d'
         'f1f00bf9331d1ef7f29b0ac29cdfcbda'
         '99d8d2838f49fa0f2f21c9e37948100d')