# $Id: PKGBUILD 87501 2013-04-02 00:06:04Z dreisner $
# Maintainer: Dave Reisner <d@falconindy.com>
# Maintainer (Parabola): Esteban Carnevale <alfplayer@mailoo.org>
# Maintainer (Parabola): André Silva <emulatorman@parabola.nu>

_pkgname=expac
pkgname=expac-relative
pkgver=3
pkgrel=1
pkgdesc="pacman database extraction utility, with dbpath and config options support"
arch=('i686' 'x86_64' 'mips64el')
url="http://github.com/falconindy/expac"
license=('GPL')
conflicts=$_pkgname
provides=$_pkgname
depends=('pacman')
makedepends=('perl')
source=("http://code.falconindy.com/archive/$_pkgname/$_pkgname-$pkgver.tar.gz"{,.sig}
        'add-options-dbpath-and-config.patch')
md5sums=('2f53f9663b69948a4a8bb03c1aa435a5'
         'SKIP'
         '30539a5f7d1acbebb393535ae8ecf570')

prepare() {
  cd "$_pkgname-$pkgver"

  patch -Np1 -i "$srcdir/add-options-dbpath-and-config.patch"

  sed '/\*\//q' expac.c >LICENSE
}

build() {
  cd "$_pkgname-$pkgver"

  make
}

package() {
  cd "$_pkgname-$pkgver"

  make PREFIX=/usr DESTDIR="$pkgdir" install

  install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$_pkgname/LICENSE"
}

# vim: ft=sh syn=sh