# $Id: PKGBUILD 198811 2013-11-05 16:40:29Z bpiotrowski $
# Maintainer: Daniel Isenmann <daniel@archlinux.org>

_pkgname=gimp
pkgname=$_pkgname-pcr
pkgver=2.8.10
pkgrel=1
pkgdesc="GNU Image Manipulation Program"
arch=('i686' 'x86_64' 'mips64el')
url="http://www.gimp.org/"
license=('GPL' 'LGPL')
depends=('pygtk' 'lcms' 'libxpm' 'libwmf' 'libxmu' 'librsvg' 'libmng' 'dbus-glib' \
         'libexif' 'gegl' 'jasper' 'desktop-file-utils' 'hicolor-icon-theme' 'babl')
makedepends=('intltool' 'webkitgtk2' 'poppler-glib' 'alsa-lib' 'iso-codes' 'curl' 'ghostscript')
optdepends=('gutenprint: for sophisticated printing only as gimp has built-in cups print support'
            'webkitgtk2: for the help browser'
            'poppler-glib: for pdf support'
            'alsa-lib: for MIDI event controller module'
            'curl: for URI support'
            'ghostscript: for postscript support')
options=('!makeflags')
provides=("$_pkgname")
conflicts=('gimp-devel' "$_pkgname")
install=gimp.install
source=(ftp://ftp.gimp.org/pub/gimp/v${pkgver%.*}/${_pkgname}-${pkgver}.tar.bz2 gnu.gpl 
        uri-backend-libcurl.patch)
md5sums=('84c964aab7044489af69f7319bb59b47'
         '2d823a7e7cd7f99b681943e42bfb7d40'
         'e894f4b2ffa92c71448fdd350e9b78c6')

prepare() {
  cd "${srcdir}/${_pkgname}-${pkgver}"

  # fixing freetype header path file
  sed -i "s|freetype/tttables[.]h|freetype2/tttables.h|" app/text/${_pkgname}font.c
}

build() {
  cd "${srcdir}/${_pkgname}-${pkgver}"
  #patch -p1 < ../uri-backend-libcurl.patch
  PYTHON=/usr/bin/python2 ./configure --prefix=/usr --sysconfdir=/etc \
    --enable-mp --enable-gimp-console --enable-gimp-remote \
    --enable-python --with-gif-compression=lzw --with-libcurl \
    --without-aa --without-hal --without-gvfs --without-gnomevfs
  make
}

package() {
  cd "${srcdir}/${_pkgname}-${pkgver}"
  make DESTDIR="${pkgdir}" install
  sed -i 's|#!/usr/bin/env python|#!/usr/bin/env python2|' "${pkgdir}"/usr/lib/gimp/2.0/plug-ins/*.py
  install -D -m644 "${srcdir}/gnu.gpl" "${pkgdir}/usr/share/gimp/2.0/palettes/GNU.gpl"

  rm "${pkgdir}/usr/share/man/man1/gimp-console.1"
  ln -s gimp-console-${pkgver%.*}.1.gz "${pkgdir}/usr/share/man/man1/gimp-console.1.gz"
  ln -s gimptool-2.0 "${pkgdir}/usr/bin/gimptool"
  ln -sf gimptool-2.0.1.gz "${pkgdir}/usr/share/man/man1/gimptool.1.gz"
}