# Maintainer (Arch): Kyle Keen <keenerd@gmail.com>
# Contributor (Arch): Dominik Heidler <dheidler@gmail.com>
# Contributor: Denis 'GNUtoo' Carikli <GNUtoo@cyberdimension.org>

_pkgname=gqrx
pkgname=gqrx-xtrx
pkgver=2.11.5
pkgrel=3
pkgdesc="Interactive SDR receiver waterfall for many devices."
arch=('armv7h' 'i686' 'x86_64')
url="http://gqrx.dk/"
license=('GPL')
depends=('qt5-svg' 'libpulse' 'gnuradio-osmosdr-xtrx' 'libxkbcommon-x11')
conflicts=('gqrx')
makedepends=('boost')
source=("https://github.com/csete/gqrx/releases/download/v$pkgver/gqrx-sdr-$pkgver-src.tar.xz")
sha512sums=('f1006c37567a6c177ec0f5d15dcef9803b5dc1b124226b552b408e4ce0b3279a845a5875bfb1d7ccd6563b41f67c07a434f325e4ee8d28db2ee19b249159d3a3')

prepare() {
  cd "$srcdir"
  echo "StartupNotify=false" >> gqrx-sdr-$pkgver/gqrx.desktop
  cp -r gqrx-sdr-$pkgver gqrx-$pkgver-alsa
  cd gqrx-$pkgver-alsa
  sed -i 's/AUDIO_BACKEND = pulse/#&/' gqrx.pro
}

build() {
  cd "$srcdir/$_pkgname-sdr-$pkgver"
  rm -rf build
  mkdir build
  cd build
  qmake PREFIX=/usr/ ..
  make
  cd "$srcdir/$_pkgname-$pkgver-alsa"
  rm -rf build
  mkdir build
  cd build
  qmake PREFIX=/usr/ ..
  make
}

package() {
  cd "$srcdir/$_pkgname-sdr-$pkgver"
  install -Dm644 "$_pkgname.desktop" "$pkgdir/usr/share/applications/$_pkgname.desktop"
  install -Dm644 "resources/icons/gqrx.svg" "$pkgdir/usr/share/pixmaps/gqrx.svg"

  cd "$srcdir/$_pkgname-sdr-$pkgver/build"
  make install INSTALL_ROOT="$pkgdir"

  cd "$srcdir/$_pkgname-$pkgver-alsa/build"
  install -Dm755 gqrx "$pkgdir/usr/bin/gqrx-alsa"
}