# Maintainer (Arch): Håvard Pettersson <mail@haavard.me>
# Contributor (Arch): Ivan Shapovalov <intelfx100 at gmail dot com>
# Maintainer: Omar Vega Ramos <ovruni@gnu.org.pe>

_pkgname=libfilteraudio
pkgname=libfilteraudio-git
pkgver=r95.ada2f4f
pkgrel=1
pkgdesc="An easy to use audio filtering library made from webrtc code"
arch=('i686' 'x86_64' 'armv7h')
url="https://github.com/irungentoo/filter_audio"
license=('BSD3')
makedepends=('git')
depends=('glibc')
provides=("${_pkgname}" 'filter_audio')
conflicts=("${_pkgname}" 'filter_audio')
source=(
    "${_pkgname}::git+https://github.com/irungentoo/libfilteraudio.git"
    'LICENSE'
)
sha512sums=('SKIP'
            'ab7ea75c03fab3dfc5d452f04a38b42783f646c2e0acaf8494628bfdf6f83e4b04d470e019385de3e89dd57eb8ef6d02daa6256d4ff311cc66f3999b694ef143')

pkgver() {
    cd ${_pkgname}
    printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

build() {
    cd ${_pkgname}
    make
}

package() {
    cd ${_pkgname}
    make DESTDIR="$pkgdir" PREFIX="/usr" install
    install -Dm644 "$srcdir/LICENSE" "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}