# Maintainer (AUR): Nicolas Iooss (nicolas <dot> iooss <at> m4x <dot> org)
# Contributor (AUR): Timothée Ravier <tim@siosm.fr>
# Contributor (AUR): Nicky726 (Nicky726 <at> gmail <dot> com)
# Contributor (AUR): Sergej Pupykin (pupykin <dot> s+arch <at> gmail <dot> com)
# Maintainer: Luke Shumaker <lukeshu@parabola.nu>

# parabola changes and rationale:
# - Added armv7h support

pkgname=libsepol
pkgver=3.2
pkgrel=1
pkgdesc="SELinux binary policy manipulation library"
arch=('i686' 'x86_64' 'armv6h')
arch+=('armv7h')
url='https://github.com/SELinuxProject/selinux'
license=('LGPL2.1')
groups=('selinux')
makedepends=('flex')
depends=('glibc')
options=(staticlibs)
conflicts=("selinux-usr-${pkgname}")
provides=("selinux-usr-${pkgname}=${pkgver}-${pkgrel}")
source=("https://github.com/SELinuxProject/selinux/releases/download/${pkgver}/${pkgname}-${pkgver}.tar.gz")
sha256sums=('dfc7f662af8000116e56a01de6a0394ed79be1b34b999e551346233c5dd19508')

build() {
  cd "${pkgname}-${pkgver}"

  export CFLAGS="${CFLAGS} -fno-semantic-interposition"
  make

  # Build a libsepol.so.1 to ease the transition from libsepol 3.1 to 3.2
  make -C src LIBVERSION=1 libsepol.so.1
  rm src/libsepol.so
}

package() {
  cd "${pkgname}-${pkgver}"
  make DESTDIR="${pkgdir}" SHLIBDIR=/usr/lib install

  install -Dm755 src/libsepol.so.1 "${pkgdir}/usr/lib"
}