# $Id: PKGBUILD 196866 2013-10-20 14:29:14Z allan $
# Maintainer (Arch): Allan McRae <allan@archlinux.org>
# Contributor (Arch): judd <jvinet@zeroflux.org>
# Maintainer: Márcio Silva <coadde@parabola.nu>

# NOTE: requires rebuilt with each new gcc version

_pkgname=libtool
pkgname=libtool-lts
pkgver=2.4.2
_gccver=4.7.3
pkgrel=1
pkgdesc="A generic library support script,"
arch=('i686' 'x86_64' 'mips64el')
url="http://www.gnu.org/software/libtool"
license=('GPL')
depends=('sh' "libltdl=$pkgver" 'tar' "gcc-lts=${_gccver}")
makedepends=("gcc-lts=${_gccver}")
groups=('lts-devel')
provides=("$_pkgname=$pkgver")
conflicts=("$_pkgname")
install=libtool.install
source=(ftp://ftp.gnu.org/pub/gnu/libtool/${_pkgname}-${pkgver}.tar.xz{,.sig})
md5sums=('2ec8997e0c07249eb4cbd072417d70fe'
         '1e6ba57420c82c663c85e745d11c7eed')

build() {
  cd ${srcdir}/${_pkgname}-${pkgver}
  ./configure --prefix=/usr
  make
}

check() {
  cd ${srcdir}/${_pkgname}-${pkgver}
  make check
}

package() {
  cd ${srcdir}/${_pkgname}-${pkgver}
  
  make DESTDIR=${pkgdir} install-binSCRIPTS install-man install-info \
                         install-data-local
  rm -r ${pkgdir}/usr/share/libtool/libltdl/
}