# $Id: PKGBUILD 78820 2012-10-25 06:47:28Z foutrelis $
# Maintainer: Jakob Gruber <jakob.gruber@gmail.com>
# Maintainer: Sven-Hendrik Haase <sh@lutzhaase.com>
# Contributor: rayte <rabyte.at.gmail.dot.com>
# Maintainer (Parabola): Márcio Silva <coadde@lavabit.com>

pkgname=luabind
pkgver=0.9.1
pkgrel=3
pkgdesc='A library that helps you create bindings between C++ and Lua'
arch=(
  i686
  x86_64
  mips64el
)
url="http://www.rasterbar.com/products/$pkgname.html"
license=MIT
makedepends=(
  boost
  boost-build
  unzip
)
depends=(
  gcc-libs
  lua51
)
source=(
  "http://downloads.sourceforge.net/$pkgname/$pkgname-$pkgver.tar.gz"
  ${pkgname}_boost.patch
)
md5sums=(
  8a323fb51d07dad5cfdb12c432793d55
  d62ae6fc635300bc659df9dbb587ac53
)

build() {
  cd $srcdir/$pkgname-$pkgver

  patch -Np1 -i $srcdir/${pkgname}_boost.patch

  # build luabind
  setarch $CARCH bjam release --prefix=$pkgdir/usr link=static,shared
}

package() {
  cd $srcdir/$pkgname-$pkgver

  setarch $CARCH bjam release --prefix=$pkgdir/usr link=static,shared install

  # copy license
  install -Dm644 $srcdir/$pkgname-$pkgver/LICENSE \
    $pkgdir/usr/share/licenses/$pkgname/LICENSE
}