# Maintainer (Arch): Denis Yantarev <denis dot yantarev at gmail dot com>
# Contributor (Arch): SJ_UnderWater
# Contributor (Arch): Dominik Dingel <mail at wodar dot de>
# Contributor (Arch): William Udovich <nerdzrule7 at earthlink dot net>
# Contributor (Arch): Farhan Yousaf <farhany at xaviya dot com>
# Maintainer: Omar Vega Ramos <ovruni@gnu.org.pe>

pkgname=netatalk
pkgver=3.1.11
pkgrel=1
pkgdesc='Open-source implementation of the Apple Filing Protocol'
arch=('i686' 'x86_64' 'armv7h')
url='http://netatalk.sourceforge.net'
license=('GPL')
depends=('avahi>=0.6' 'libldap' 'libgcrypt>=1.2.3' 'libevent' 'python2' 'dbus-glib' 'python2-dbus' 'pam')
replaces=('netatalk-git' 'netatalk2')
backup=('etc/afp.conf'
	'etc/extmap.conf')
install=$pkgname.install
source=(http://downloads.sourceforge.net/project/$pkgname/$pkgname/$pkgver/$pkgname-$pkgver.tar.bz2
	python2.patch)
sha256sums=('3434472ba96d3bbe3b024274438daad83b784ced720f7662a4c1d0a1078799a6'
	'582337cd434f5f3c89a00d99162747bd5f9ada57eef234ef8b49c16be7c19346')

prepare() {
	cd "$srcdir/$pkgname-$pkgver"
	patch -p0 < "$srcdir/python2.patch"
}

build() {
	cd "$srcdir/$pkgname-$pkgver"
	autoreconf -fi
	CFLAGS="-Wno-unused-result -O2" \
		./configure --prefix=/usr --localstatedir=/var/state --sysconfdir=/etc \
		--sbindir=/usr/bin --enable-silent-rules --with-init-style=systemd \
		--with-cracklib --with-cnid-cdb-backend --enable-pgp-uam --with-libevent=no
	make
}

package() {
	cd "$srcdir/$pkgname-$pkgver"
	make DESTDIR="$pkgdir" install
}