# Maintainer (Arch): Jakob Gahde <j5lx@fmail.co.uk>
# Contributor (Arch): Serge Zirukin <ftrvxmtrx@gmail.com>
# Contributor (Arch): Sergei Lebedev <superbobry@gmail.com
# Contributor (Arch): serp <serp256 at gmail dot com>
# Maintainer: Omar Vega Ramos <ovruni@gnu.org.pe>

_pkgname=lwt
pkgname=ocaml-${_pkgname}
pkgver=2.5.1
pkgrel=1
pkgdesc="A library for cooperative threads in OCaml"
arch=('i686' 'x86_64')
url="http://ocsigen.org/${_pkgname}/"
license=('LGPL')
depends=('ocaml' 'camlp4' 'ocaml-ppx_tools' 'ocaml-react' 'ocaml-ssl' 'libev' 'glib2')
makedepends=('ocaml-findlib')
source=(https://github.com/ocsigen/${_pkgname}/archive/$pkgver.tar.gz)
sha256sums=('351ea57e30cdeeebb02ae3b12906ed391f947fd35d57148905828ee121ec29ec')
options=(!strip !makeflags staticlibs)

build() {
  cd "${srcdir}/${_pkgname}-${pkgver}"

  echo '<src/top/*.*>: use_compiler_libs' >> _tags
  # What requires what?
  # --enable-glib      glib2
  # --enable-react     ocaml-react
  # --enable-ssl       ocaml-ssl

  ./configure --enable-react \
              --enable-glib \
              --enable-ssl \
              --enable-camlp4 \
              --enable-ppx \
              --disable-debug \
              --prefix /usr \
              --destdir $pkgdir
  make
}


package() {
  cd "${srcdir}/${_pkgname}-${pkgver}"

  export OCAMLFIND_DESTDIR="${pkgdir}/$(ocamlfind printconf destdir)"
  mkdir -p "$OCAMLFIND_DESTDIR/stublibs"
  
  make install
  install -Dm 644 "LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}