# Maintainer: fauno
# Based on the git version by
# Maintainer: Robert Štětka <robert dot stetka at gmail dot com>
pkgname=perspectives-server
pkgver=3.4.1
pkgrel=1
url='https://perspectives-project.org/'
pkgdesc='Perspectives notary server'
arch=('any')
license=('GPL3')
depends=('openssl' 'python2>=2.7' 'python2-m2crypto'
         'python2-cherrypy' 'python2-sqlalchemy')
source=("https://repo.parabola.nu/other/${pkgname}/${pkgname}-${pkgver}.tar.gz"
        perspectives-server.{conf,cron,service,install})
install="${pkgname}.install"
optdepends=('python2-psycopg2: for postgresql storage'
            'memcache: for caching'
            'redis: for caching')
md5sums=('d83a2a254951f4bb710860bafdd16351'
         '00c42be9b00186cd660645a0cf20fa4b'
         '2343fe5f9756ffd7a70e39d04ba21d46'
         '870bf3020c73c02853cf1c0d1668d005'
         '7d51646e864e895d13a3eb682ebf78ec')

mkdepends=('git')
mksource=("$pkgname-$pkgver::git+https://github.com/danwent/Perspectives-Server/#tag=v$pkgver")
mkmd5sums=('SKIP')

mksource() {
  :
}

package() {
  install -dm 750 ${pkgdir}/usr/share/webapps/${pkgname}
  install -dm 750 ${pkgdir}/etc/webapps/${pkgname}

  install -Dm 640 ${srcdir}/${pkgname}.conf \
                  ${pkgdir}/etc/conf.d/${pkgname}.conf

  install -Dm 755 ${srcdir}/${pkgname}.cron \
                  ${pkgdir}/etc/cron.daily/${pkgname}

  cp -av "$srcdir/$pkgname-$pkgver/"* \
         "${pkgdir}/usr/share/webapps/${pkgname}/"

  install -Dm 644 ${srcdir}/${pkgname}.service \
                  ${pkgdir}/usr/lib/systemd/system/${pkgname}.service
}


# vim:set ts=2 sw=2 et: