# Maintainer (aur): Kingan <kingan201 at gmail dot com>
# Contributor: Frederic Bezies <fredbezies at gmail dot com>
# Contributor: Valsu [arch(at)hylia.de]

# parabola changes and rationale:
# - use --disable-cpu-opt, otherwise it use -mach=native and the resulting
#   binary is only meant to run on the machine that compiled it: this option
#   generates SMID (SSE3, AVX, etc) instructions in a way that is impossible to
#   disable it at runtime. So running it on a machine without the same extended
#   instruction set generally result in illegal instructions.

pkgname=prboom-plus
pkgver=2.5.1.4
pkgrel=2
pkgdesc='An advanced, Vanilla-compatible Doom engine based on PrBoom'
url='http://prboom-plus.sourceforge.net/'
arch=('x86_64' 'i686')
arch+=('armv7h')
license=('GPL2')
depends=('fluidsynth' 'glu' 'libmad' 'portmidi' 'sdl_image' 'sdl_mixer' 'sdl_net')
conflicts=('prboom')
replaces=('prboom')
provides=('prboom')
source=("http://download.sourceforge.net/prboom-plus/prboom-plus-$pkgver.tar.gz")
sha256sums=('e0e2241d174839b107f1a42b191aa9895dc6749e477cbc850ad520fba2353b94')

build() {
  cd "prboom-plus-$pkgver"

  ./configure --prefix=/usr --without-dumb --disable-cpu-opt
  make
}

package() {
  cd "prboom-plus-$pkgver"

  make DESTDIR="$pkgdir" gamesdir=/usr/bin install
}