# Contributor (Arch): boenki <boenki at gmx dot de>
# Contributor (Arch): Arkham <arkham at archlinux dot us>
# Contributor (Arch): Christoph Zeiler <rabyte*gmail>
# Contributor (Arch): Marcin Karpezo <sirmacik at gmail dot com>
# Contributor (Arch): Lucas Salies Brum <lucas at archlinux dot com dot br>
# Contributor (Arch): max.bra <max.bra at alice dot it>
# Maintainer        : Omar Vega Ramos <ovruni@gnu.org.pe>

pkgname=pyrenamer
pkgver=0.6.0
pkgrel=9
pkgdesc="Mass file renamer"
arch=('any')
url="http://www.infinicode.org"
license=('GPL2')
depends=('python2-gconf')
makedepends=('perl-xml-parser')
optdepends=('hachoir-metadata: rename multimedia files metadata'
            'python2-eyed3: rename MP3 files metadata')
install=$pkgname.install
source=(http://ftp.de.debian.org/debian/pool/main/p/pyrenamer/pyrenamer_0.6.0.orig.tar.gz)
md5sums=('a7159f803cd919ab76f17789189c577b')

prepare() {
  cd $pkgname-$pkgver
  sed -i 's|python python2 python2.5|python2 python2.5|' configure
  sed -i 's|PYTHON=python|PYTHON=python2|' py-compile
  sed -i 's|#!/usr/bin/env python|#!/usr/bin/env python2|' src/$pkgname
}

build() {
  cd $pkgname-$pkgver
  ./configure --prefix=/usr --sysconfdir=/etc \
    --with-gconf-schema-file-dir=/usr/share/gconf/schemas
  make
}

package() {
  cd $pkgname-$pkgver
  make DESTDIR="$pkgdir" install
}