# Maintainer: Omar Vega Ramos <ovruni@gnu.org.pe>

pkgbase=python-simpleeval
pkgname=('python-simpleeval' 'python2-simpleeval')
pkgver=0.8.7
pkgrel=1
pkgdesc='Simple Safe Extensible Expression Evaluator for Python'
arch=(any)
url="https://pypi.python.org/pypi/simpleeval"
license=('MIT')
makedepends=('python-setuptools' 'python2-setuptools')
source=("https://github.com/danthedeckie/simpleeval/archive/$pkgver.tar.gz")
md5sums=('3bb26dee1a183990f1ba38552d589b79')

prepare() {
  cp -a simpleeval-$pkgver{,-py2}
}

build() {
  cd "$srcdir/simpleeval-$pkgver"
  python setup.py build

  cd "$srcdir/simpleeval-$pkgver-py2"
  python2 setup.py build
}

package_python-simpleeval() {
  depends=('python')

  cd "$srcdir/simpleeval-$pkgver"
  python setup.py install --root="$pkgdir" --optimize=1
  install -Dm644 "LICENCE" "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
}

package_python2-simpleeval() {
  depends=('python2')

  cd "$srcdir/simpleeval-$pkgver-py2"
  python2 setup.py install --root="$pkgdir" --optimize=1
  install -Dm644 "LICENCE" "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
}