# Maintainer: Márcio Silva <coadde@hyperbola.info>

pkgbase=python-simpletal
pkgname=(python-simpletal python2-simpletal)
_pkgname=SimpleTAL
pkgver=5.2
_pkgver=4.3 # It's needs for Python 2
pkgrel=2
license=('BSD3')
pkgdesc='A Python implementation of the TAL, TALES and METAL specification'
arch=('any')
makedepends=('python' 'python2')
url="https://www.owlfish.com/software/${_pkgname,}"
source=("$url/downloads/$_pkgname-$pkgver.tar.gz"
        "$url/downloads/$_pkgname-$_pkgver.tar.gz")
sha512sums=('16b46886af50f697e706c6b3f0400707299cfe40a81773fbd094de2f52ca8a87438f3ae7477462d0523570b3e3248d2ad4bb2affd3a7088fc45b1201ed228fbe'
            '5246f00abc26801ff6b4950f28783fd9a1c124bb61be48f0f6cc4ab6cabe149566bc6f4edf7bc1cc625a8ee469cdd9a4824ee8390057a2c39896791ec1d73e45')

build() {
  cd $srcdir/$_pkgname-$pkgver
  python setup.py build
  cd $srcdir/$_pkgname-$_pkgver
  python2 setup.py build
}

package_python-simpletal() {
  depends=('python')
  cd $srcdir/$_pkgname-$pkgver
  python setup.py install --root=$pkgdir
}

package_python2-simpletal() {
  depends=('python2')
  pkgver=$_pkgver
  cd $srcdir/$_pkgname-$_pkgver
  python2 setup.py install --root=$pkgdir
}