# Maintainer: Max Meyer <dev@fedux.org>
# Contributor: Sven Wick <sven.wick@gmx.de>
#
# Please fork and send me a pull request for changes to package build file(s)
# Url: https://github.com/maxmeyer/archlinux-recutils
#

pkgname=recutils
pkgver=1.5
pkgrel=2
pkgdesc="GNU tools and libraries to access human-editable, text-based databases."
arch=(i686 x86_64 mips64el)
url="http://www.gnu.org/software/recutils/"
license=('GPL3')
depends=(libgcrypt curl)
optdepends=("mdbtools: for processing M$ Access databases")
#options=()
install=recutils.install
changelog=ChangeLog
source=("http://ftp.gnu.org/gnu/recutils/$pkgname-$pkgver.tar.gz"
	"recutils-1.5-glibc-2.16.patch")
sha256sums=('7ed67e74468084f52ad9341e4b11c44e5fd9d5325b93b7eb2cb230c839ff5dec'
	    '28c169df3573748215a78b78793d45a09aeefc6194cf1185c7c0f11881eb289a')
options=(!libtool)

build() {
  cd "$srcdir/$pkgname-$pkgver"
  patch -Np1 -i ${srcdir}/recutils-1.5-glibc-2.16.patch
  ./configure --prefix=/usr
  make
}

check() {
  cd "$srcdir/$pkgname-$pkgver"
  make check
}

package() {
  cd "$srcdir/$pkgname-$pkgver"

  make DESTDIR="$pkgdir/" install
}

# vim:set ts=2 sw=2 et: