# Maintainer: Kete < kete at ninthfloor dot org >

pkgname=seeks
pkgver=0.4.1
pkgrel=6
pkgdesc="A social decentralized internet overlay for collaborative searches"
arch=('i686' 'x86_64')
url="http://www.seeks-project.info/site/"
license=('AGPL3' 'LGPL' 'BSD')
backup=('etc/logrotate.d/seeks'
    'etc/conf.d/seeks'
    'etc/seeks/config')
depends=('curl' 'libevent>=2.0' 'libxml2' 'opencv' 'protobuf' 'icu' 'tokyotyrant')
makedepends=('pkg-config' 'docbook-xml' 'docbook2x')
source=("http://downloads.sourceforge.net/project/${pkgname}/hippy/${pkgname}-${pkgver}.tar.gz"
'seeks.conf.d'
	'seeks.rc.d'
	'img_websearch.patch'
	'conf.patch'
	'seeks.logrotate')
install=seeks.install

build() {
  cd  "$srcdir/$pkgname-$pkgver"
  # replace <cxflann.h> by <cv.h>
  patch -p1 -i "$srcdir/img_websearch.patch"

  # linking issue with --as-needed linker flag, Cli not building with RC2
  LDFLAGS="-Wl,--no-as-needed" \
  ./configure --prefix=/usr \
              --sysconfdir=/etc \
              --enable-httpserv-plugin \
              --enable-extended-host-patterns
              #--disable-cli \

  sed -i s/,--as-needed,/,/ config.status
  make
}

check() {
  cd  "$srcdir/$pkgname-$pkgver"
  make -k check-local
}

package() {
  cd  "$srcdir/$pkgname-$pkgver"
  # Patch config file to make seeks log in /var/log instead of ./ (needed for rc.d)
  patch -p1 -i "$srcdir/conf.patch"
  make DESTDIR="$pkgdir/" install

  install -D -m644 Licenses  "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
  install -D -m644 ../seeks.conf.d "${pkgdir}/etc/conf.d/seeks"
  install -D -m755 ../seeks.rc.d "${pkgdir}/etc/rc.d/seeks"
  install -D -m600 ../seeks.logrotate  "${pkgdir}/etc/logrotate.d/seeks"
  install -d -m755  "${pkgdir}/var/log/seeks"
  install -d -m755  "${pkgdir}/var/lib/seeks"
}

# vim:set ts=2 sw=2 et:
md5sums=('2545192be5fa2e70d850f7395d039a0f'
         'ed29089d43873600726d570e63a5043d'
         '72a00a931363edd2ed11c0072bfd5b10'
         '2554e9f9f733d83203d0926e599e66db'
         '71a99dafa726539b9de9055468e2f56c'
         '5fbdf9c327999605b0f124132f27a27d')