# $Id: PKGBUILD 59836 2011-11-30 22:56:23Z giovanni $
# Maintainer: Giovanni Scafora <giovanni@archlinux.org>
# Contributor: Larry Hajali <larryhaja [at] gmail [dot] com>
# Contributor: Jorge Araya Navarro <jorgean@lavabit.com>

pkgname=sigil
pkgver=0.7.2
pkgrel=1
pkgdesc="A WYSIWYG ebook editor"
arch=('i686' 'x86_64')
url="http://code.google.com/p/sigil/"
license=('GPL3')
depends=('qt5-base' 'qt5-svg' 'qt5-webkit' 'qt5-xmlpatterns' 'qt5-tools')
makedepends=('cmake')
provides=('sigil')
conflicts=('sigil')
install=sigil.install
source=("http://sigil.googlecode.com/files/Sigil-0.7.2-Code.zip"
	"sigil.desktop")

build() {
    cd ${srcdir}
    mkdir build
    cd build
    cmake -G "Unix Makefiles" \
	-DCMAKE_INSTALL_PREFIX=/usr \
	-DCMAKE_C_FLAGS:STRING="${CFLAGS}" \
	-DCMAKE_CXX_FLAGS:STRING="${CXXFLAGS}" \
	-DCMAKE_BUILD_TYPE=Release \
	-DCMAKE_SKIP_RPATH=ON ..

    make
}

package() {
  cd "${srcdir}"/build
  make install DESTDIR="${pkgdir}"

  install -d -m 0755 "${pkgdir}"/usr/share/applications
  install -m 0644 "${srcdir}"/sigil.desktop "${pkgdir}"/usr/share/applications

  for _pic in 16 32 48 128 256; do
      install -D -m 0644 ../src/Sigil/Resource_Files/icon/app_icon_${_pic}.png \
	  "${pkgdir}"/usr/share/icons/hicolor/${_pic}x${_pic}/apps/sigil.png
  done
}
sha256sums=('8a6f5fd7c59fd8524ce0f48e7d13d13bad137053c9071fe2e1653ea55d5ed940'
            '92a1014794dbf81fa997449338ded9a0e84593e3552020eb9269039b916bea36')