# Maintainer (Arch): Jaroslav Lichtblau <dragonlord@aur.archlinux.org>
# Maintainer: André Silva <emulatorman@parabola.nu>

pkgname=suricata
pkgver=3.0
pkgrel=1
pkgdesc="A Free Software Next Generation Intrusion Detection and Prevention Engine"
arch=('i686' 'x86_64' 'armv7h')
url="http://suricata-ids.org/"
license=('GPL2')
depends=('libcap-ng' 'libnet' 'libpcap' 'libyaml' 'pcre')
optdepends=('snort: suricata can use rulesets provided by snort')
backup=('etc/suricata/suricata.yaml')
source=(http://openinfosecfoundation.org/download/$pkgname-$pkgver.tar.gz)
sha256sums=('4b8feb398a0800c955fe24aa31ca446c539e79492155717e826473f902c8e65a')

prepare() {
  cd "${srcdir}"/$pkgname-$pkgver

  # remove Open Source term
  sed -i 's|Open Source|Free Software|;
         ' $(grep -ril 'open source')
}

build() {
  cd "${srcdir}"/$pkgname-$pkgver

  ./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var
  make
}

package() {
  cd "${srcdir}"/$pkgname-$pkgver

  make DESTDIR="${pkgdir}" install

  install -d "${pkgdir}"/var/log/$pkgname

  install -Dm644 $pkgname.yaml "${pkgdir}"/etc/$pkgname/$pkgname.yaml
  install -Dm644 classification.config "${pkgdir}"/etc/$pkgname/classification.config
  install -Dm644 reference.config "${pkgdir}"/etc/$pkgname/reference.config

  install -d "${pkgdir}"/etc/$pkgname/rules
  install -Dm644 rules/*.rules "${pkgdir}"/etc/$pkgname/rules/
}