# Maintainer: Omar Vega Ramos <ovruni@gnu.org.pe>
# Maintainer (Manjaro): artoo <artoo@manjaro.org>
# Contributor (Manjaro): Mattias Andrée <`base64 -d`(bWFhbmRyZWUK)@member.fsf.org>
# Maintainer (Arch Linux): Eric Belanger <eric@archlinux.org>

pkgname=sysvinit
pkgver=2.88
pkgrel=16.2
pkgdesc='Linux System V Init'
url='http://www.nongnu.org/sysvinit/'
arch=('i686' 'x86_64' 'armv7h')
license=('GPL')
depends=('glibc')
conflicts=('systemd-sysvcompat')

source=("http://download.savannah.gnu.org/releases/sysvinit/sysvinit-${pkgver}dsf.tar.bz2"
        "0001-simplify-writelog.patch"
        "0002-remove-ansi-escape-codes-from-log-file.patch")
sha256sums=('60bbc8c1e1792056e23761d22960b30bb13eccc2cabff8c7310a01f4d5df1519'
            '8126d09a35bdb9137bb19dc31b58cf1e829137fba34f7dcde7598018e1736826'
            '90d38e4351ef9d77088661b411eb2b20eda435676e1e407f3d959ca2064d5c1e')

prepare() {
    cd "$srcdir/$pkgname-${pkgver}dsf"

    # FS#30005
    patch -p1 -d "src" -i "$srcdir/0001-simplify-writelog.patch"
    patch -p1 -d "src" -i "$srcdir/0002-remove-ansi-escape-codes-from-log-file.patch"
}

build() {
    cd "$srcdir/$pkgname-${pkgver}dsf"
    make
}

package() {
    cd "$srcdir/$pkgname-${pkgver}dsf"

    mkdir -p "$pkgdir/usr/bin"
    ln -s usr/bin "$pkgdir/bin"
    ln -s usr/bin "$pkgdir/sbin"
    make ROOT="$pkgdir" install
    rm "$pkgdir/bin" "$pkgdir/sbin"

    local rmprogs=(
        # provided by util-linux
        last
        lastb
        mesg
        mountpoint
        sulogin
        utmpdump
        wall
        # provided by procps-ng
        pidof
    )
    cd "$pkgdir"
    local prog
    for prog in "${rmprogs[@]}"; do
        rm usr/bin/"$prog" usr/share/man/man?/"$prog".?
    done

    # old Arch Linux sysvinit would have split out fstab-decode,
    # killall5, and bootlogd into a separate sysvinit-tools package.
    # Unfortunately, because sysvinit-tools provided pidof, procps-ng
    # still conflicts=(sysvinit-tools).
}