# Maintainer (aur): Christian Hesse <mail@eworm.de>
# Maintainer: Isaac David <isacdaavid@at@isacdaavid@dot@info>

pkgname=tox-prpl
pkgver=0.5.1
pkgrel=1
pkgdesc='Tox protocol plugin for pidgin / libpurple'
arch=('i686' 'x86_64' 'armv7h')
url='http://tox.dhs.org/'
license=('GPL3')
depends=('libpurple' 'toxcore')
makedepends=('git' 'libconfig')
optdepends=('pidgin: Use tox in pidgin messenger')
options=('!libtool')
conflicts=('tox-prpl')
provides=('tox-prpl')

source=("${pkgname}-${pkgver}.tar.gz::https://github.com/jin-eld/${pkgname}/archive/v${pkgver}.tar.gz"
	'tox_callback_user_data_handling.patch')
sha256sums=('51d18bd7c6a39991b70ed8aacc165796713fb252f7438498794a65abf80ce935'
            'f2d07bdfa0ddc01fdcb83be51cb29da135e81a748c34b5c51f2c42868537d478')

prepare() {
	cd "$pkgname-$pkgver"
	patch -Np1 < ../tox_callback_user_data_handling.patch
}

build() {
	cd "$pkgname-$pkgver"

	autoreconf -i
	./configure --prefix=/usr
	make
}

package() {
	cd "$pkgname-$pkgver"
	make DESTDIR="$pkgdir" install
}