# Maintainer: Márcio Silva <coadde@parabola.nu>

pkgname=tupi
pkgver=0.2.git20140724
pkgcommit=ed31be0cb13892bc6839a58da3d1570e1f49876b # July 24, 2014
pkgrel=1
pkgdesc='Tupí is an 2D animation/drawing software (fork of KToon)'
arch=(
  x86_64
  i686
)
url=http://www.maefloresta.com/portal/
license=GPL2
depends=(
  desktop-file-utils
  ffmpeg
  quazip
  qt5-multimedia
  qt5-svg
  shared-mime-info
  xdg-utils
)
makedepends=(
  git
  qt5-tools
  ruby
)
install=$pkgname.install
source=$pkgname-$pkgver::git+git://anongit.kde.org/tupi#commit=$pkgcommit
sha512sums=SKIP

prepare() {
  cd $pkgname-$pkgver
  # fix /lib directory path
  sed -i 's|/lib64|/lib|' configure.rb qonf/{configure,test}.rb
  # fix qmake path
  sed -i 's|qmake|qmake-qt5|g' configure
  sed -i '\|path| s|qmake|qmake-qt5|
          s|/bin/qmake|/bin/qmake-qt5|
         ' qonf/qmake.rb
  # fix /usr directory path
  sed -i 's|/opt/|/usr/|' qonf/configure.rb
}

build() {
  cd $pkgname-$pkgver
  export QTDIR=/usr
  ./configure --prefix=/usr
  make
}

package() {
  cd $pkgname-$pkgver
  make DESTDIR=$pkgdir install
}