# Maintainer: Márcio Silva <coadde@parabola.nu>

_pkgname=xpra
pkgname=$_pkgname-gtk2
pkgver=0.17.1
pkgrel=2
pkgdesc='multi-platform X11 screen and application forwarding system'
arch=('i686' 'x86_64' 'armv7h')
license=('GPL2')
url="https://www.$_pkgname.org"
backup=("etc/$_pkgname/"{xorg,$_pkgname}".conf")
depends=('pygtk' 'ffmpeg' 'python2-cairo' 'xorg-server') # 'xvidcore': needs similar to support xvid
optdepends=('cups: CUPS (printing) support'
            'python2-lcms: LittleCMS support'
            'python2-lz4: LZ4 compression support'
            'python2-lzo: LZO compression support'
            'python2-pycups: CUPS (printing) support'
            'python2-pyopencl: OpenCL support'
            'x11-ssh-askpass: OpenSSH passphrase dialog support'
            'xf86-video-dummy: Xdummy support')
makedepends=('cups' 'cython2' 'lsb-release' 'xf86-video-dummy')
conflicts=("$_pkgname")
source=("$url/src/$_pkgname-$pkgver.tar.xz")
sha1sums=('9303e0ca5d60e5f9d5497b1012ce7829dc642dec')

build () {
  cd $_pkgname-$pkgver
  CFLAGS="$CFLAGS -fno-strict-aliasing" python2 setup.py build \
    --with-{csc_opencl,gtk_x11,server,shadow,verbose,Xdummy{,_wrapper}} --without-{csc_libyuv,xvid}
  cd rencode
  python2 setup.py build
}

package() {
  cd $_pkgname-$pkgver
  python2 setup.py install --root=$pkgdir
  cd rencode
  python2 setup.py install --root=$pkgdir
}