# Maintainer: SJ_UnderWater
# Maintainer (Parabola): fauno@parabola.nu
# Based on netatalk package :
# Maintainer: Dominik Dingel <mail at wodar dot de>
# Contributor: William Udovich <nerdzrule7 at earthlink dot net>
# Contributor: Farhan Yousaf <farhany at xaviya dot com>

pkgname=netatalk
pkgver=3.0.1
pkgrel=3
pkgdesc='Open Source AFP fileserver'
arch=('i686' 'x86_64')
url='http://netatalk.sourceforge.net'
license=('GPL')
depends=('avahi>=0.6' 'libldap' 'libgcrypt>=1.2.3' 'libevent')
backup=('etc/afp.conf')
options=('!libtool')
install=$pkgname.install
changelog=$pkgname.changelog
source=(http://iweb.dl.sourceforge.net/project/$pkgname/$pkgname/$pkgver/$pkgname-$pkgver.tar.bz2)
md5sums=('b4f5c932b2ca99f5292bd6b6d69b3ebc')

build() {
  cd $pkgname-$pkgver

# TODO what does this fix?
  msg2 'Fixing...'
  sed -i 's/x"linux/x"generic/' macros/netatalk.m4
  sed -i 's:/lib:/usr/lib:' distrib/initscripts/Makefile.{am,in}

  autoreconf

  CFLAGS="-Wno-unused-result" \
  ./configure --prefix=/usr \
              --disable-static \
              --localstatedir=/var/state \
              --sysconfdir=/etc \
              --with-init-style=systemd \
              --with-cracklib \
              --with-cnid-cdb-backend \
              --enable-pgp-uam \
              --without-libevent-header \
              --without-libevent-lib

  sed -i -e s/-Ino// -e s/-Lno// etc/netatalk/Makefile
  make 
}
package() {
  cd $pkgname-$pkgver

  make DESTDIR="$pkgdir" install
}