# $Id: PKGBUILD 161437 2012-06-11 15:10:57Z juergen $
# Maintainer: Juergen Hoetzel <juergen@archlinux.org>
# Contributor: Renchi Raju <renchi@green.tam.uiuc.edu>

_pkgname=emacs
pkgname=emacs-lucid
pkgver=24.1
pkgrel=2
pkgdesc="emacs, with the lucid toolkit rather than GTK2"

provides=("$_pkgname=$pkgver")
conflicts=("$_pkgname")

arch=('i686' 'x86_64')
url="http://www.gnu.org/software/emacs/emacs.html"
license=('GPL3')
depends=('librsvg' 'gpm' 'giflib' 'libxpm' 'gtk-update-icon-cache' 'libxaw' 'hicolor-icon-theme' 'gconf' 'desktop-file-utils' 'alsa-lib' 'imagemagick')
install=emacs.install
source=(ftp://ftp.gnu.org/gnu/emacs/$_pkgname-$pkgver.tar.bz2{,.sig} gnulib.patch)

build() {
  cd "$srcdir"/$_pkgname-$pkgver

  # This is from Gentoo, to deal with a newer version of gnulib
  patch -p1 -i "$srcdir/gnulib.patch"
  # This is to deal with a newer version of autoconf
  autoreconf -i -I m4

  ./configure --prefix=/usr --sysconfdir=/etc --libexecdir=/usr/lib \
    --localstatedir=/var --with-x-toolkit=lucid --with-xft
  make
}

package() {
  cd "$srcdir"/$_pkgname-$pkgver
  make DESTDIR="$pkgdir" install

  # remove conflict with ctags package
  mv "$pkgdir"/usr/bin/{ctags,ctags.emacs}
  mv "$pkgdir"/usr/share/man/man1/{ctags.1.gz,ctags.emacs.1}
  # fix all the 777 perms on directories
  find "$pkgdir"/usr/share/emacs -type d -exec chmod 755 {} \;
  # fix user/root permissions on usr/share files
  find "$pkgdir"/usr/share/emacs -exec chown root:root {} \;
  # fix perms on /var/games
  chmod 775 "$pkgdir"/var/games
  chmod 775 "$pkgdir"/var/games/emacs
  chmod 664 "$pkgdir"/var/games/emacs/*
  chown -R root:games "$pkgdir"/var/games
}
md5sums=('8ba0932c498bc8fb10d7ddba52227e5b'
         'c303d5c0bd0f7ea28acd14c9738faff4'
         'f9192850960902d90504150f08be4a81')