# Maintainer: Luke Shumaker <lukeshu@sbcglobal.net>

_pkgname=emacsutils
pkgname=$_pkgname-git

_pkgver=0.9
pkgver=20170716
_gitver='commit=efecac8688ffd15e292a9cca722e16bdb97795e6'
pkgdesc="Utilities for interacting with GNU Emacs from a *NIX environment"
url="https://lukeshu.com/git/$_pkgname.git"
license=('GPL3')

provides=("$_pkgname=$_pkgver")
conflicts=("$_pkgname")

pkgrel=2
arch=('any')

depends=('emacs')
source=("https://repo.parabola.nu/other/~lukeshu/$_pkgname/$pkgname-$pkgver.tar.gz")
md5sums=('521559ae048f29361fe786ce6f25e3b6')

mkdepends=('git')
mksource=(".$pkgname-$pkgver::git://git.lukeshu.com/$_pkgname.git#$_gitver")
mkmd5sums=('SKIP')

mksource() {
        cd "$srcdir/.$pkgname-$pkgver"
        make dist
        mv "$_pkgname"-*/ ../"$pkgname-$pkgver"
}

_config=(
  VERSION=${_pkgver}.${pkgver}
  prefix=/usr
  libexecdir='$(libdir)'
)
        
build() {
  cd "$srcdir/$pkgname-$pkgver"
  make "${_config[@]}"
}

package() {
  cd "$srcdir/$pkgname-$pkgver"
  make "${_config[@]}" install DESTDIR="$pkgdir"
}