# Maintainer (Parabola): Luke Shumaker <lukeshu@sbcglobal.net>
# Maintainer (Arch): Eric Belanger <eric@archlinux.org>
# Contributor: Tom Newsom <Jeepster@gmx.co.uk>

_pkgname=freeglut
pkgname=freeglut26
pkgver=2.6.0
pkgrel=2
pkgdesc="Provides functionality for small OpenGL programs"
arch=('i686' 'x86_64')
url="http://freeglut.sourceforge.net/"
license=('MIT')
depends=('libxxf86vm' 'mesa' 'libxi')
replaces=('glut')
provides=('glut')
conflicts=('glut')
provides+=("$_pkgname=$pkgver")
options=('!libtool')
source=(http://downloads.sourceforge.net/freeglut/${_pkgname}-${pkgver}.tar.gz \
        2.6.0-GFX_radeon.patch)
md5sums=('39f0f2de89f399529d2b981188082218' '6d0a018fe4f0bc9ace2b244ca59514d3')
sha1sums=('68306c4486c13d005a4e4d54035e0c0b1bdc220b' '2e392c7d0b60016ec89e6a5edf504f5722351b95')

build() {
  cd "${srcdir}/${_pkgname}-${pkgver}"
  # fixes an issue with the radeon[hd] ATI opensource drivers
  # ref: http://bugs.gentoo.org/show_bug.cgi?id=295163
  patch -p0 -i "${srcdir}/2.6.0-GFX_radeon.patch"

  ./autogen.sh
  ./configure --prefix=/usr --disable-static
  make
}

package() {
  cd "${srcdir}/${_pkgname}-${pkgver}"
  make DESTDIR="${pkgdir}" install
  install -Dm644 COPYING "${pkgdir}/usr/share/licenses/${_pkgname}/LICENSE"
}