summaryrefslogtreecommitdiff
path: root/java/byaccj/PKGBUILD
blob: 10f2bef95f097c5018a3c04ad37427595a91fe44 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
# Maintainer: Luke Shumaker <lukeshu@sbcglobal.net>
# Maintainer (AUR): <ying@althonx4>

pkgname=byaccj
pkgver=1.15
pkgdesc="Berkeley yacc with Java output"
url="http://byaccj.sourceforge.net/"
license=('custom:Public Domain')

pkgrel=1
arch=('i686' 'x86_64' 'mips64el')
source=(http://downloads.sourceforge.net/project/byaccj/${pkgname}/${pkgver}/${pkgname}${pkgver}_src.tar.gz
        http://metadata.ftp-master.debian.org/changelogs/main/b/byacc-j/byacc-j_${pkgver}-1_copyright
        ldflags.patch)
md5sums=('5ee9959af35f245ac2c4355f85fdf351'
         'cc9e2ed821e7f2e5ef8f2be0fdc97b46'
         '76fd678b41d614497cf77c6dba5de63e')

prepare() {
  cd "$srcdir"/$pkgname$pkgver
  patch -Np1 -i ../ldflags.patch
}

build() {
  cd "$srcdir"/$pkgname$pkgver
  make -C src linux CFLAGS="$CFLAGS" LDFLAGS="$LDFLAGS"
}

package() {
  cd "$srcdir"/$pkgname$pkgver
  install -Dm755 src/yacc.linux "$pkgdir"/usr/bin/byaccj
  install -Dm644 src/yacc.1     "$pkgdir"/usr/share/man/man1/byaccj.1
  install -d                    "$pkgdir"/usr/share/doc/$pkgname
  install  -m644 docs/*      -t "$pkgdir"/usr/share/doc/$pkgname
  install -Dm644 ../byacc-j_$pkgver-1_copyright "$pkgdir"/usr/share/licenses/$pkgname/copyright
}