blob: 769e6acf57233c3f58d9c8a49165eb2bf6d1d7f2 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
|
# Maintainer: Sébastien Luttringer
# Contributor: Tom Gundersen <teg@jklm.no>
pkgname=filesystem
pkgver=2018.8
pkgrel=1
pkgdesc='Base Arch Linux files'
arch=(x86_64 ppc64le)
license=('GPL')
url='https://www.archlinux.org'
groups=('base')
depends=('iana-etc')
backup=('etc/crypttab' 'etc/fstab' 'etc/group' 'etc/gshadow' 'etc/host.conf'
'etc/hosts' 'etc/issue' 'etc/ld.so.conf' 'etc/motd' 'etc/nsswitch.conf'
'etc/passwd' 'etc/profile' 'etc/resolv.conf' 'etc/securetty'
'etc/shadow' 'etc/shells')
source=('crypttab' 'env-generator' 'fstab' 'group' 'gshadow' 'host.conf' 'hosts'
'issue' 'ld.so.conf' 'locale.sh' 'motd' 'nsswitch.conf' 'os-release'
'passwd' 'profile' 'resolv.conf' 'securetty' 'shadow' 'shells' 'sysctl'
'sysusers' 'tmpfiles')
md5sums=('5fa6674df7645d7f5895f2d12b4ef4e9'
'2b0344e9639f35f3c0d5637a23556089'
'e33f6dfdd61978fcb3ddf1431286e05a'
'7fed1e1fb855e41a6d64d41f8521d69a'
'1c1e3b08acfa286f4b417c49de3e4366'
'7d119a9cce152aa182fb3392ddeecea7'
'a1315ea3e2b64d197b6efaf9c14ff778'
'7813c481156f6b280a3ba91fc6236368'
'5deb9f890a4d08a245e9752ede77271e'
'580cf8b59eebfaac4fad373ffadc9912'
'd41d8cd98f00b204e9800998ecf8427e'
'981ee4d7e506a9d6d9ed2d872e16004b'
'0a0fbb8e64faabb40023bd180d7190a1'
'5182ac38a0de85da8ade93ef71975ca4'
'2c79e1762978235e7b4a9ef595f6c029'
'0ee015fad07732676d9488ae498eed41'
'f04bcb2803afc4dcb95670fe87343b4d'
'f64466dd77c7bec37a8b47681468211a'
'a78cd8d7f8240a8448edee82f503c34e'
'a51847c012555c843dbdf8df0da171d3'
'af7832eabaac9804c22f1f2b53816a49'
'0267a3a463f35eec8a31f40a720dfd86')
package() {
cd "$pkgdir"
# setup root filesystem
for d in boot dev etc home mnt usr var opt srv/http run; do
install -d -m755 $d
done
install -d -m555 proc
install -d -m555 sys
install -d -m0750 root
install -d -m1777 tmp
# vsftpd won't run with write perms on /srv/ftp
# ftp (uid 14/gid 11)
install -d -m555 -g 11 srv/ftp
# setup /etc and /usr/share/factory/etc
install -d etc/{ld.so.conf.d,skel,profile.d} usr/share/factory/etc
for f in fstab group host.conf hosts issue ld.so.conf motd nsswitch.conf \
passwd resolv.conf securetty shells profile; do
install -m644 "$srcdir"/$f etc/
install -m644 "$srcdir"/$f usr/share/factory/etc/
done
ln -s ../proc/self/mounts etc/mtab
for f in gshadow shadow crypttab; do
install -m600 "$srcdir"/$f etc/
install -m600 "$srcdir"/$f usr/share/factory/etc/
done
touch etc/arch-release
install -m755 "$srcdir"/locale.sh etc/profile.d/locale.sh
install -Dm644 "$srcdir"/os-release usr/lib/os-release
# setup /var
for d in cache local opt log/old lib/misc empty; do
install -d -m755 var/$d
done
install -d -m1777 var/{tmp,spool/mail}
# allow setgid games (gid 50) to write scores
install -d -m775 -g 50 var/games
ln -s spool/mail var/mail
ln -s ../run var/run
ln -s ../run/lock var/lock
# setup /usr hierarchy
for d in bin include lib share/misc src; do
install -d -m755 usr/$d
done
for d in {1..8}; do
install -d -m755 usr/share/man/man$d
done
# add lib symlinks
ln -s usr/lib lib
[[ $CARCH = 'x86_64' ]] && {
ln -s usr/lib lib64
ln -s lib usr/lib64
}
# add bin symlinks
ln -s usr/bin bin
ln -s usr/bin sbin
ln -s bin usr/sbin
# setup /usr/local hierarchy
for d in bin etc games include lib man sbin share src; do
install -d -m755 usr/local/$d
done
ln -s ../man usr/local/share/man
# setup systemd-sysctl
install -D -m644 "$srcdir"/sysctl usr/lib/sysctl.d/10-arch.conf
# setup systemd-sysusers
install -D -m644 "$srcdir"/sysusers usr/lib/sysusers.d/arch.conf
# setup systemd-tmpfiles
install -D -m644 "$srcdir"/tmpfiles usr/lib/tmpfiles.d/arch.conf
# setup systemd.environment-generator
install -D -m755 "$srcdir"/env-generator usr/lib/systemd/system-environment-generators/10-arch
}
# vim:set ts=2 sw=2 et:
|
