summaryrefslogtreecommitdiff
path: root/libre-testing/systemd/PKGBUILD
blob: 5ed190d80805fe390a4a25ddf0e637ab2077cf1f (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
# Maintainer (Arch): Christian Hesse <mail@eworm.de>
# Maintainer (Arch): Dave Reisner <dreisner@archlinux.org>
# Maintainer (Arch): Tom Gundersen <teg@jklm.no>
# Maintainer: Luke Shumaker <lukeshu@parabola.nu>
# Contributor: Omar Vega Ramos <ovruni@gnu.org.pe>
# Contributor: Denis 'GNUtoo' Carikli <GNUtoo@cyberdimension.org>

pkgbase=systemd
pkgname=('systemd' 'libsystemd' 'systemd-resolvconf' 'systemd-sysvcompat')
pkgname+=('systemd-common' 'systemd-udev')
# We split Arch's libsystemd into systemd-$X, for the following $X:
_libsystemd=('libsystemd' 'libudev' 'nss-systemd' 'nss-myhostname' 'nss-mymachines' 'nss-resolve')
pkgname+=("${_libsystemd[@]/#/systemd-}")
# Can be from either systemd or systemd-stable
_commit='0430af90ef28a229e51136ad364e1da7e76c8638'
pkgver=240.95
pkgrel=1
pkgrel+=.parabola4
arch=('x86_64')
arch+=('i686' 'armv7h' 'ppc64le')
url='https://www.github.com/systemd/systemd'
makedepends=('acl' 'cryptsetup' 'docbook-xsl' 'gperf' 'lz4' 'xz' 'pam' 'libelf'
             'intltool' 'iptables' 'kmod' 'libcap' 'libidn2' 'libgcrypt'
             'libmicrohttpd' 'libxslt' 'util-linux' 'linux-api-headers'
             'python-lxml' 'quota-tools' 'shadow' 'git'
             'meson' 'libseccomp' 'pcre2' 'audit' 'kexec-tools' 'libxkbcommon'
             'bash-completion')
makedepends_i686=('gnu-efi-libs' 'pkgconf')
makedepends_x86_64=('gnu-efi-libs')
options=('strip')
validpgpkeys=('63CDA1E5D3FC22B998D20DD6327F26951A015CC4'  # Lennart Poettering <lennart@poettering.net>
              '5C251B5FC54EB2F80F407AAAC54CA336CFEB557E') # Zbigniew Jędrzejewski-Szmek <zbyszek@in.waw.pl>
source=(# fragment is latest tag for source verification, final merge in prepare()
        "git+https://github.com/systemd/systemd-stable#tag=v${pkgver%.*}?signed"
        "git+https://github.com/systemd/systemd#tag=v${pkgver%.*}?signed"
        '0001-Use-Arch-Linux-device-access-groups.patch'
        'initcpio-hook-udev'
        'initcpio-install-systemd'
        'initcpio-install-udev'
        'parabola.conf'
        'loader.conf'
        'splash-parabola.bmp'
        'systemd-user.pam'
        'systemd-hook'
        'udev-hook'
        'systemd-binfmt.hook'
        'systemd-catalog.hook'
        'systemd-daemon-reload.hook'
        'systemd-hwdb.hook'
        'systemd-sysctl.hook'
        'systemd-sysusers.hook'
        'systemd-tmpfiles.hook'
        'systemd-udev-reload.hook'
        'systemd-update.hook'
        '0001-FSDG-man-Refer-to-the-operating-system-as-GNU-Linux.patch'
        '0002-FSDG-os-release-Default-PRETTY_NAME-to-GNU-Linux-ins.patch'
        '0003-FSDG-os-release-Default-NAME-to-GNU-Linux-instead-of.patch'
        '0004-FSDG-os-release-Default-ID-to-gnu-linux-instead-of-l.patch'
        '0005-FSDG-systemd-resolved-Fallback-hostname-to-gnu-linux.patch'
        '0006-FSDG-man-Use-FSDG-operating-systems-as-examples.patch'
        '0007-FSDG-bootctl-Say-Systemd-Boot-Manager-instead-of-Lin.patch')
sha512sums=('SKIP'
            'SKIP'
            '9348683829190628e25b7b3300fd880c426d555bde330d5fc5150a9a54b3ad9d4d1f2e69ea1dc6d6f086693dacc53c5af30f1fa7ad9b479791fd77bcdafa430e'
            'f0d933e8c6064ed830dec54049b0a01e27be87203208f6ae982f10fb4eddc7258cb2919d594cbfb9a33e74c3510cfd682f3416ba8e804387ab87d1a217eb4b73'
            '01de24951a05d38eca6b615a7645beb3677ca0e0f87638d133649f6dc14dcd2ea82594a60b793c31b14493a286d1d11a0d25617f54dbfa02be237652c8faa691'
            'a25b28af2e8c516c3a2eec4e64b8c7f70c21f974af4a955a4a9d45fd3e3ff0d2a98b4419fe425d47152d5acae77d64e69d8d014a7209524b75a81b0edb10bf3a'
            '70b3f1d6aaa9cd4b6b34055a587554770c34194100b17b2ef3aaf4f16f68da0865f6b3ae443b3252d395e80efabd412b763259ffb76c902b60e23b6b522e3cc8'
            '6c6f579644ea2ebb6b46ee274ab15110718b0de40def8c30173ba8480b045d403f2aedd15b50ad9b96453f4ad56920d1350ff76563755bb9a80b10fa7f64f1d9'
            'a50bc85061a9a16d776235099867bc1a17c17dddb74c1ecf5614c849735a9779c5e34e5ddca8ca6af4b59a40f57c08ecf219b98cab09476ddb0f110e6a35e45c'
            'b90c99d768dc2a4f020ba854edf45ccf1b86a09d2f66e475de21fe589ff7e32c33ef4aa0876d7f1864491488fd7edb2682fc0d68e83a6d4890a0778dc2d6fe19'
            '12abea62121f4e0867ffbcf6ba96bb1540dd7d86775556fc180ae6c844abfd13310b6782ff6d0e665c8d875446c17b40495d6c2fbc7ddcb42f9a13e1b57a8c40'
            'b7ee4f212c910df62c3472103a64a3cdf0d31292bc2f8fa839e5c86f34faa3ef1a3693601f5716779c4552a0d2b1d57538d45610f4c2e1c80e155ffbf0af187d'
            '5a6b6beef8c31c79018884d948de840f4d3dfb07d9a87081ebf65e2b8fe595bc8c96dbd7742920ccf948c233213ed0026abc913650cefd77ad90c6f8c89bddb8'
            '4cff2ebd962e26e2f516d8b4ac45c839dbfa54dd0588b423c224a328b9f7c62306ca7b2f6cb55240c564caf9972d5bcd2e0efaf2de49d64729aeb3bc1560c9eb'
            '872de70325e9798f0b5a77e991c85bd2ab6de24d9b9ba4e35002d2dd5df15f8b30739a0042a624776177ffc14a838cde7ee98622016ed41df3efda9a659730b2'
            '96bb157de6921086a2bfc45a650414fbffa787bccff2cbd838cbe05c6fc635cbabd533360608eb7ca2f80ab7df795065a27abf4a1b1ea2b406612a3fcf420bdc'
            'da783e3bfc6469b92dee4064a13e2b427520d3d96b57c95a4e07aaca3e844d95210a8b16122b022080f5452d65096f274dd1c1467725bbdb2e40ef304b78774a'
            '08a590d08043a21f30f04252164b94df972b1ff1022a0469d6aef713e14484a3a037cce290a2a582851e6fac3e64add69d6cc8fc130bbeeaea08626ebf3e1763'
            '577e33a1c50b4b41157a67f64162b035dd0c4a541e19cee55a100048bdb50cb2c82852741b1372989a0fe4c4782ba477522747fcc81d72aed99b3db512a86447'
            'c4463fdd25e14a836ac3b874109861a55a0169c4206b6356b53974dd4621f645652087ebf4c738b18734a718fe7fd9ec6b700ce8dd9736525274eb16b10385e6'
            '209b01b044877cc986757fa4009a92ea98f480306c2530075d153203c3cd2b3afccab6aacc1453dee8857991e04270572f1700310705d7a0f4d5bed27fab8c67'
            'a40678af1cd677535fb71084f70a10b74e61592c48a7f3901d6b51429c0bae179208b4aebd6700871fdf334d67703c955f01a0cd5165571f53435783c457d568'
            'ff25035b5ed7b7b1720850573235159dee3d3aa5ca042cd5249094727f0e1d9dbf249d5612a1f2fefc20ed1618000277f2c3542ac513465764a98a3405455be2'
            'fd0df3d365892d4d461a78bb0b728201e81c1269af07a38e134fadfc0ffb29aade7642142d128abcf88803b86494d7629ff5990359ef067feea3d476c7238a67'
            'e9e884015a40dc796fd8cbd8f79b3b9eebc7e48a332b22d52104c21c492be9982b35b7dd30bc29f2c2d274707ffd043eda059659844a4cd50eb433b8a3f7648c'
            '0d6b894149ec8d0612d1be1dee5daa1768345232e450435ddc750e36a8309dd96782a92f0220169c69103b1c4632af708e4a737cb7ba817944c92dcb61379a30'
            'cf0dd60f56160f6add80ecebf698632bde55ed25e54ffa6cd0fa18da4aa2d446d3e4394295446555db22d32bf3b5f563c7e77a52eeb342a8ddaabd1347032e83'
            '28a5b3fc9e2c5cec9267bb96725c73ee77788514f140c0cf8df765af64bc8130dd02f4863d9128ac45d54256b2ab4f2b06d1a3f65660ce1dfba5727618cd1839')

_backports=(
  # https://github.com/systemd/systemd/issues/11259
  '8ca9e92c742602b8bcd431001e6f5b78c28c184f'
)

_reverts=(
)

prepare() {
  cd "$pkgbase-stable"

  # add upstream repository for cherry-picking
  git remote add -f upstream ../systemd
  # merge the latest stable commit (fast-foward only to make sure
  # the verified tag is in)
  git merge --ff-only "${_commit}"

  local _c
  for _c in "${_backports[@]}"; do
    git cherry-pick -n "${_c}"
  done
  for _c in "${_reverts[@]}"; do
    git revert -n "${_c}"
  done

  # Replace cdrom/dialout/tape groups with optical/uucp/storage
  patch -Np1 -i ../0001-Use-Arch-Linux-device-access-groups.patch

  # apply FSDG patches
  local _patch
  for _patch in "$srcdir"/????-FSDG-*.patch; do
    patch -Np1 -i "$_patch"
  done
}

pkgver() {
  cd "$pkgbase-stable"

  local _version _count
  _version="$(git describe --abbrev=0 --tags)"
  _count="$(git rev-list --count ${_version}..)"
  printf '%s.%s' "${_version#v}" "${_count}"
}

build() {
  local _timeservers=({0..3}.arch.pool.ntp.org)
  local _nameservers=(
    # We use these public name services, ordered by their
    # privacy policy (hopefully):
    #  * Cloudflare (https://1.1.1.1/)
    #  * Quad9 without filtering (https://www.quad9.net/)
    #  * Google (https://developers.google.com/speed/public-dns/)
    1.1.1.1
    9.9.9.10
    8.8.8.8
    2606:4700:4700::1111
    2620:fe::10
    2001:4860:4860::8888
  )

  if [ "$CARCH" = "armv7h" ]; then
    LDFLAGS+=" -Wl,-fuse-ld=bfd"
    CFLAGS+=" -fno-lto"
    CXXFLAGS+=" -fno-lto"
  fi

  local _meson_options=(
    -Dima=false
    -Dlibidn2=true
    -Dlz4=true

    -Ddbuspolicydir=/usr/share/dbus-1/system.d
    -Ddefault-hierarchy=hybrid
    -Ddefault-locale=C
    -Ddefault-kill-user-processes=false
    -Dfallback-hostname='parabola'
    -Ddns-servers="${_nameservers[*]}"
    -Dntp-servers="${_timeservers[*]}"
    -Drpmmacrosdir=no
    -Dsysvinit-path=
    -Dsysvrcnd-path=
  )
  if [ "$CARCH" != "armv7h" ]; then
    _meson_options+=(-Dgnu-efi=true)
  fi

  arch-meson "$pkgbase-stable" build "${_meson_options[@]}"

  ninja -C build

  # Go ahead and split the package now.  It's easier this way, because
  # we can use mv instead of awkward, error-prone rm/cp pairs.
  rm -rf "$srcdir/dest"

  # Put things in the main systemd package by default
  DESTDIR="$srcdir/dest/systemd" meson install -C build

  install -dm755 "$srcdir/dest/common"/usr/lib/systemd
  mv -T "$srcdir/dest"/{systemd,common}/usr/lib/systemd/libsystemd-shared-${pkgver%%.*}.so

  install -dm755 "$srcdir/dest/libsystemd"/usr/{lib/pkgconfig,share/man/man3,include}
  mv -T "$srcdir/dest"/{systemd,libsystemd}/usr/include/systemd
  mv -T "$srcdir/dest"/{systemd,libsystemd}/usr/lib/pkgconfig/libsystemd.pc
  mv "$srcdir/dest"/systemd/usr/lib/libsystemd.so*      -t "$srcdir/dest"/libsystemd/usr/lib/
  mv "$srcdir/dest"/systemd/usr/share/man/man3/{SD,sd}* -t "$srcdir/dest"/libsystemd/usr/share/man/man3/

  install -dm755 "$srcdir/dest/libudev"/usr/{lib/pkgconfig,share/man/man3,include}
  mv -T "$srcdir/dest"/{systemd,libudev}/usr/include/libudev.h
  mv -T "$srcdir/dest"/{systemd,libudev}/usr/lib/pkgconfig/libudev.pc
  mv "$srcdir/dest"/systemd/usr/lib/libudev.so*       -t "$srcdir/dest"/libudev/usr/lib/
  mv "$srcdir/dest"/systemd/usr/share/man/man3/*udev* -t "$srcdir/dest"/libudev/usr/share/man/man3/

  install -dm755 "$srcdir/dest/udev"/{etc,usr/lib}
  mv -T "$srcdir/dest"/{systemd,udev}/etc/udev/
  mv -T "$srcdir/dest"/{systemd,udev}/usr/lib/udev/
  while read -d '' -r file; do
    install -dm755 "$srcdir/dest/udev/${file%/*}"
    mv -T "$srcdir/dest/systemd/$file" "$srcdir/dest/udev/$file"
  done < <(find "$srcdir/dest/systemd" \( -name '*udev*' -o -name '*hwdb*' \) -printf '%P\0')

  local nssmodule
  for nssmodule in systemd myhostname mymachines resolve; do
    install -dm755 "$srcdir/dest/nss-$nssmodule"/usr/{lib,share/man/man8}
    mv -t "$srcdir/dest"/nss-$nssmodule/usr/share/man/man8/ -- \
       "$srcdir/dest"/systemd/usr/share/man/man8/nss-$nssmodule.8 \
       "$srcdir/dest"/systemd/usr/share/man/man8/libnss_$nssmodule.*.8
    mv "$srcdir/dest"/systemd/usr/lib/libnss_$nssmodule.so* -t "$srcdir/dest"/nss-$nssmodule/usr/lib/
  done

  install -dm755 "$srcdir/dest/systemd-sysvcompat"/usr/share/man/man8
  mv "$srcdir/dest/systemd"/usr/share/man/man8/{halt,poweroff,reboot,runlevel,shutdown,telinit}.8 \
     -t "$srcdir/dest/systemd-sysvcompat"/usr/share/man/man8

  rmdir "$srcdir/dest"/systemd/usr/{share/man/man3,lib/pkgconfig,include}
}

check() {
  meson test -C build
}

package_systemd() {
  pkgdesc='system and service manager'
  license=('LGPL2.1')
  groups=('base-devel')
  depends=('bash' 'dbus' 'kbd' 'kmod'
           'libsystemd' 'pam' 'libelf'
           'util-linux' 'pcre2')
  depends+=("systemd-common=$pkgver-$pkgrel" 'udev')
  provides=("systemd-tools=$pkgver")
  replaces=('systemd-tools')
  conflicts=('systemd-tools')
  optdepends=('libmicrohttpd: remote journald capabilities'
              'quota-tools: kernel-level quota management'
              'systemd-sysvcompat: symlink package to provide sysvinit binaries'
              'polkit: allow administration as unprivileged user'
              'curl: machinectl pull-tar and pull-raw')
  backup=(etc/pam.d/systemd-user
          etc/systemd/coredump.conf
          etc/systemd/journald.conf
          etc/systemd/journal-remote.conf
          etc/systemd/journal-upload.conf
          etc/systemd/logind.conf
          etc/systemd/system.conf
          etc/systemd/timesyncd.conf
          etc/systemd/resolved.conf
          etc/systemd/user.conf)
  install=systemd.install

  cp -rT -d --no-preserve=ownership,timestamp "$srcdir/dest/$pkgname" "$pkgdir"

  # don't write units to /etc by default. some of these will be re-enabled on
  # post_install.
  rm -rv "$pkgdir"/etc/systemd/system/*

  # we'll create this on installation
  rmdir "$pkgdir"/var/log/journal/remote

  # executable (symlinks) shipped with systemd-sysvcompat
  rm "$pkgdir"/usr/bin/{halt,init,poweroff,reboot,runlevel,shutdown,telinit}

  # files shipped with systemd-resolvconf
  rm "$pkgdir"/usr/{bin/resolvconf,share/man/man1/resolvconf.1}

  # avoid a potential conflict with [core]/filesystem
  rm "$pkgdir"/usr/share/factory/etc/nsswitch.conf
  sed -i '/^C \/etc\/nsswitch\.conf/d' "$pkgdir"/usr/lib/tmpfiles.d/etc.conf

  # add back tmpfiles.d/legacy.conf, normally omitted without sysv-compat
  install -m0644 $pkgbase-stable/tmpfiles.d/legacy.conf "$pkgdir"/usr/lib/tmpfiles.d

  # ship default policy to leave services disabled
  echo 'disable *' >"$pkgdir"/usr/lib/systemd/system-preset/99-default.preset

  # add mkinitcpio hooks
  install -D -m0644 initcpio-install-systemd "$pkgdir"/usr/lib/initcpio/install/systemd

  # ensure proper permissions for /var/log/journal
  # The permissions are stored with named group by tar, so this works with
  # users and groups populated by systemd-sysusers. This is only to prevent a
  # warning from pacman as permissions are set by systemd-tmpfiles anyway.
  install -d -o root -g systemd-journal -m 2755 "$pkgdir"/var/log/journal

  # match directory owner/group and mode from [extra]/polkit
  install -d -o root -g 102 -m 0750 "$pkgdir"/usr/share/polkit-1/rules.d

  # add example bootctl configuration
  install -D -m0644 parabola.conf "$pkgdir"/usr/share/systemd/bootctl/parabola.conf
  install -D -m0644 loader.conf "$pkgdir"/usr/share/systemd/bootctl/loader.conf
  install -D -m0644 splash-parabola.bmp "$pkgdir"/usr/share/systemd/bootctl/splash-parabola.bmp

  # pacman hooks
  install -D -m0755 systemd-hook "$pkgdir"/usr/share/libalpm/scripts/systemd-hook
  install -D -m0644 -t "$pkgdir"/usr/share/libalpm/hooks *.hook
  rm -- "$pkgdir"/usr/share/libalpm/hooks/*{udev,hwdb}*

  # overwrite the systemd-user PAM configuration with our own
  install -D -m0644 systemd-user.pam "$pkgdir"/etc/pam.d/systemd-user
}

package_systemd-common() {
  pkgdesc='systemd files shared between split packages'
  license=('LGPL2.1')
  depends=('acl' 'cryptsetup' 'libdbus' 'glibc' 'iptables' 'libcap'
           'libgcrypt' 'libidn2' 'libidn2.so' 'libseccomp' 'libsystemd.so'
           'libudev.so' 'libblkid.so' 'libmount.so' 'libuuid.so' 'lz4'
           'xz' 'audit')

  cp -rT -d --no-preserve=ownership,timestamp "$srcdir/dest/${pkgname#systemd-}" "$pkgdir"
}

package_systemd-udev() {
  pkgdesc='Userspace device file manager'
  license=('GPL2') # NB: different than the rest
  groups=('base' 'base-devel')
  depends=("systemd-common=$pkgver-$pkgrel" 'systemd-libudev'
           'hwids' 'kmod' 'util-linux' 'zlib')
  backup=(etc/udev/udev.conf)

  provides+=("${pkgname#systemd-}=$pkgver")
  conflicts+=("${pkgname#systemd-}")
  replaces+=("${pkgname#systemd-}")

  cp -rT -d --no-preserve=ownership,timestamp "$srcdir/dest/${pkgname#systemd-}" "$pkgdir"

  # add mkinitcpio hooks
  install -D -m0644 initcpio-install-udev "$pkgdir"/usr/lib/initcpio/install/udev
  install -D -m0644 initcpio-hook-udev "$pkgdir"/usr/lib/initcpio/hooks/udev

  # pacman hooks
  install -D -m0755 udev-hook "$pkgdir"/usr/share/libalpm/scripts/udev-hook
  install -D -m0644 -t "$pkgdir"/usr/share/libalpm/hooks *{udev,hwdb}*.hook
}

package_libsystemd() {
  pkgdesc='systemd client libraries metapackage'
  depends=("${_libsystemd[@]/libsystemd/libsystemd.so}")
  license=('LGPL2.1')
}

package_systemd-libsystemd() {
  pkgdesc='systemd client library'
  depends=('glibc' 'libcap' 'libgcrypt' 'lz4' 'xz')
  license=('LGPL2.1')
  provides=('libsystemd.so')

  provides+=("libsystemd-standalone=$pkgver")
  conflicts+=('libsystemd-standalone')
  replaces+=('libsystemd-standalone')

  cp -rT -d --no-preserve=ownership,timestamp "$srcdir/dest/${pkgname#systemd-}" "$pkgdir"
}

package_systemd-libudev() {
  pkgdesc='systemd library for enumerating and introspecting local devices'
  groups=('base' 'base-devel') # match systemd-udev
  depends=('glibc' 'libcap')
  license=('LGPL2.1')
  provides=('libudev.so')

  provides+=("${pkgname#systemd-}=$pkgver")
  conflicts+=("${pkgname#systemd-}")
  replaces+=("${pkgname#systemd-}")

  cp -rT -d --no-preserve=ownership,timestamp "$srcdir/dest/${pkgname#systemd-}" "$pkgdir"
}

package_systemd-nss-systemd() {
  pkgdesc='NSS module providing user and group resolution for dynamic users and groups'
  depends=('glibc' 'libcap')
  license=('LGPL2.1')

  provides+=("${pkgname#systemd-}=$pkgver")
  conflicts+=("${pkgname#systemd-}")
  replaces+=("${pkgname#systemd-}")

  cp -rT -d --no-preserve=ownership,timestamp "$srcdir/dest/${pkgname#systemd-}" "$pkgdir"
}

package_systemd-nss-myhostname() {
  pkgdesc='NSS module providing hostname resolution for the locally configured system hostname'
  depends=('glibc' 'libcap')
  license=('LGPL2.1')

  provides+=("${pkgname#systemd-}=$pkgver")
  conflicts+=("${pkgname#systemd-}")
  replaces+=("${pkgname#systemd-}")

  cp -rT -d --no-preserve=ownership,timestamp "$srcdir/dest/${pkgname#systemd-}" "$pkgdir"
}

package_systemd-nss-mymachines() {
  pkgdesc='NSS module providing hostname resolution for local systemd-machined container instances'
  depends=('glibc' 'libcap')
  license=('LGPL2.1')

  provides+=("${pkgname#systemd-}=$pkgver")
  conflicts+=("${pkgname#systemd-}")
  replaces+=("${pkgname#systemd-}")

  cp -rT -d --no-preserve=ownership,timestamp "$srcdir/dest/${pkgname#systemd-}" "$pkgdir"
}

package_systemd-nss-resolve() {
  pkgdesc='NSS module providing hostname resolution via systemd-resolved'
  depends=('glibc' 'libcap')
  license=('LGPL2.1')

  provides+=("${pkgname#systemd-}=$pkgver")
  conflicts+=("${pkgname#systemd-}")
  replaces+=("${pkgname#systemd-}")

  cp -rT -d --no-preserve=ownership,timestamp "$srcdir/dest/${pkgname#systemd-}" "$pkgdir"
}

package_systemd-resolvconf() {
  pkgdesc='systemd resolvconf replacement (for use with systemd-resolved)'
  license=('LGPL2.1')
  depends=('systemd')
  provides=('openresolv' 'resolvconf')
  conflicts=('openresolv')

  replaces+=('notsystemd-resolvconf') # notsystemd-resolvconf should have never existed

  install -d -m0755 "$pkgdir"/usr/bin
  ln -s resolvectl "$pkgdir"/usr/bin/resolvconf

  install -d -m0755 "$pkgdir"/usr/share/man/man1
  ln -s resolvectl.1.gz "$pkgdir"/usr/share/man/man1/resolvconf.1.gz
}

package_systemd-sysvcompat() {
  pkgdesc='sysvinit compat for systemd'
  license=('LGPL2.1')
  groups=('base')
  provides=('init')
  conflicts=('init' 'sysvinit')
  depends=('systemd')

  cp -rT -d --no-preserve=ownership,timestamp "$srcdir/dest/$pkgname" "$pkgdir"

  install -d -m0755 "$pkgdir"/usr/bin
  ln -s ../lib/systemd/systemd "$pkgdir"/usr/bin/init
  for tool in runlevel reboot shutdown poweroff halt telinit; do
    ln -s systemctl "$pkgdir"/usr/bin/$tool
  done
}

# vim:ft=sh syn=sh et sw=2: