summaryrefslogtreecommitdiff
path: root/libre-testing/uboot4extlinux-chiliboard/PKGBUILD
blob: 5e6de9222df51c546eb3a9b0a394ec4d9717ff78 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
# U-Boot: ChiliBoard
# Maintainer: Isaac David <isacdaavid@at@isacdaavid@dot@info>
# Contributor: André Silva <emulatorman@parabola.nu>

pkgname=uboot4extlinux-chiliboard
pkgver=2014.07
pkgrel=3
pkgdesc="U-Boot with Extlinux support for ChiliBoard"
arch=('armv7h')
url="http://git.denx.de/u-boot.git/"
conflicts=('uboot-chiliboard' 'uboot4grub-chiliboard')
makedepends=('bc')
license=('GPL')
backup=(boot/extlinux/extlinux.conf)
install=${pkgname}.install
source=("ftp://ftp.denx.de/pub/u-boot/u-boot-${pkgver}.tar.bz2"
        '0001-kernel-add-support-for-gcc-7.patch'
        '0002-ARM-asm-io.h-use-static-inline.patch'
        '0003-common-main.c-make-show_boot_progress-__weak.patch'
        '0004-common-board_f-cosmetic-use-__weak-for-leds.patch'
        '0005-chiliboard-support.patch'
        '0006-parabola-arm-modifications.patch'
        'extlinux.conf'
        'uEnv.txt')
sha256sums=('b4f83b8db325c21671a997198ec3a373e2e00dde2fcf17be9b9afd7cfd727f56'
            '9e80aa27cccdb07b03d56a970f247c91d586d0b936868c076c20acc2e68a3968'
            '91b2711f36fbe1bae5d02b3a1eec81383ffd50a4b71426b82920cfd70af40237'
            '0bb7ddee0b33ba7ca830f09b6aaacc945c7a662749a19b128eb1cab71f5b100a'
            '2795b55f0ef03aef6c05fd074ab9839d0f89fdc5a3c99dd849eb74cd09e59045'
            'af804b3dd8167c61c79dfc831d34558cf8ce981dfea3df9da7f98acaee2a0edf'
            '1fca49c07c65708a1b167560c73af12d59d7e5da92794f47ecf2a27d4f765793'
            'e96d167d99967ebefde8d02b27b4564e46409cc0c8738d5de72f431a2e438cf8'
            '7882bc2f75089c83c0c3b0a22bfb5a10d3700545e600f616910bd6cdecc79237')

prepare() {
  cd u-boot-${pkgver}
  patch -Np1 -i ../0001-kernel-add-support-for-gcc-7.patch
  patch -Np1 -i ../0002-ARM-asm-io.h-use-static-inline.patch
  patch -Np1 -i ../0003-common-main.c-make-show_boot_progress-__weak.patch
  patch -Np1 -i ../0004-common-board_f-cosmetic-use-__weak-for-leds.patch
  patch -Np1 -i ../0005-chiliboard-support.patch
  patch -Np1 -i ../0006-parabola-arm-modifications.patch
}

build() {
  cd u-boot-${pkgver}

  unset CFLAGS CXXFLAGS LDFLAGS

  make distclean
  make chiliboard_config
  make
}

package() {
  cd u-boot-${pkgver}
  mkdir -p "${pkgdir}"/boot/extlinux
  cp MLO u-boot.img "${srcdir}"/uEnv.txt "${pkgdir}"/boot
  cp "${srcdir}"/extlinux.conf "${pkgdir}"/boot/extlinux
}