blob: f1945a1de64f7d75f95a46ea59c7465ea0109783 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
|
# $Id: PKGBUILD 290817 2017-03-14 08:05:30Z arojas $
# Maintainer (Arch): Ronald van Haren <ronald@archlinux.org>
# Contributor (Arch): Andrea Scarpino <andrea@archlinux.org>
# Contributor (Arch): Tobias Powalowski <tpowa@archlinux.org>
# Maintainer: André Silva <emulatorman@hyperbola.info>
# Contributor: Márcio Silva <coadde@hyperbola.info>
# Contributor: jc_gargma <jc_gargma@iserlohn-fortress.net>
pkgbase=digikam
pkgname=kipi-plugins
_pkgver=5.6.0
pkgver=${_pkgver//-/_} # for beta versions
pkgrel=2.parabola1
pkgdesc="Digital photo management application for KDE"
arch=('i686' 'x86_64' 'armv7h')
license=('GPL')
url="http://www.digikam.org/"
replaces=("${pkgname}-libre")
conflicts=("${pkgname}-libre")
makedepends=('extra-cmake-modules' 'libkipi' 'libksane' 'liblqr' 'opencv' 'boost'
'doxygen' 'lensfun' 'eigen' 'kdoctools' 'marble-common' 'kdesignerplugin'
'kfilemetadata' 'akonadi-contacts' 'qtav' 'threadweaver' 'kcalcore'
'knotifyconfig' 'libmediawiki' 'libkvkontakte')
source=("https://download.kde.org/stable/${pkgbase}/${pkgbase}-${_pkgver}.tar.xz"
"libre.patch"
'0001-optionally-enable-OpenGL.patch')
sha512sums=('015024aaff6193ca29072f7340d62982b50467d84b69bac38f60319eaf771ce2a570a514e62fefc54f194b0c27df0c36980b1eed3433023a2d8290f24cc8905d'
'403da9ea61560a7e03f519f7da0373439da162ba73d1e5c90e4e1f65146faf216644d1aa04c88519fae78767154cac720be5281ef2d9ead9b920d1e0c5e00921'
'8a5f06f916465ffa59712a49ac2dc3482093ceae1d77250ae66a5f1a469387b4052840c5fe569afe809fcd2f01eda863e4acecf2104a11c11874c28d82c34113')
prepare() {
mkdir -p build
# sv docs fail to build
sed -e '/sv/d' -i $pkgbase-$pkgver/doc-translated/CMakeLists.txt
cd ${pkgbase}-${_pkgver}
patch -p1 -i ../libre.patch
# OpenGL switch
if [[ "$CARCH" = arm* ]]; then
cd core
patch -p1 -i ${srcdir}/0001-optionally-enable-OpenGL.patch
fi
}
build() {
cd build
if [[ "$CARCH" = arm* ]]; then
local cmake_extra="-DENABLE_OPENGL=OFF"
fi
cmake ../${pkgbase}-${_pkgver} \
-DCMAKE_INSTALL_PREFIX=/usr \
-DCMAKE_INSTALL_LIBDIR=lib \
-DCMAKE_BUILD_TYPE=Release \
-DBUILD_TESTING=OFF \
-DENABLE_KFILEMETADATASUPPORT=ON \
-DENABLE_MEDIAPLAYER=ON \
-DENABLE_AKONADICONTACTSUPPORT=ON \
-DENABLE_MYSQLSUPPORT=ON \
-DENABLE_OPENCV3=ON \
-DENABLE_APPSTYLES=ON \
$cmake_extra
make
}
package_kipi-plugins() {
pkgdesc="A collection of plugins extending the KDE graphics and image applications as digiKam, without nonfree suggestions"
depends=('kio' 'libkipi')
optdepends=('libmediawiki: MediaWiki Export plugin'
'libkvkontakte: VKontakte.ru Exporter plugin')
cd build/extra
make DESTDIR="$pkgdir" install
cd $srcdir/build/po
make DESTDIR="$pkgdir" install
# Provided by digikam
rm "$pkgdir"/usr/share/locale/*/LC_MESSAGES/digikam.mo
}
|
