blob: 0f41eed123bebcbaa8bfcffe633788e632d19d9a (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
|
# $Id$
# Maintainer (Arch): Jan Alexander Steffens (heftig) <jan.steffens@gmail.com>
# Contributor (Arch): Jan de Groot <jgc@archlinux.org>
# Maintainer: Isaac David <isacdaavid@at@isacdaavid@dot@info>
# parabola changes and rationale:
# - removed unace recommendation
pkgname=file-roller
pkgver=3.26.2
pkgrel=1.parabola1
pkgdesc="Create and modify archives, without nonfree unace recommendation"
url="https://wiki.gnome.org/Apps/FileRoller"
arch=(x86_64 i686 armv7h)
license=(GPL)
depends=(gtk3 dconf libarchive file json-glib libnotify zip unzip)
makedepends=(intltool itstool docbook-xsl gnome-common git libnautilus-extension)
optdepends=('p7zip: 7z, arj, exe and encrypted zip files support'
'unrar: better RAR archive support'
'lrzip: lrzip archive support')
groups=(gnome)
_commit=723d45e7c437f87303fd0203132b5770d2775d87 # tags/3.26.2^0
source=("git+https://git.gnome.org/browse/file-roller#commit=$_commit")
sha256sums=('SKIP')
pkgver() {
cd $pkgname
git describe --tags | sed 's/-/+/g'
}
prepare() {
cd $pkgname
NOCONFIGURE=1 ./autogen.sh
}
build() {
cd $pkgname
./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var \
--libexecdir=/usr/lib/$pkgname --disable-static --disable-schemas-compile
sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
make
}
package() {
cd $pkgname
make DESTDIR="$pkgdir" install
}
|
