blob: 67b4743c6d98e2bfb4736ba67202387250c7679c (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
|
# Maintainer (Arch): Lukas Fleischer <lfleischer@archlinux.org>
# Contributor (Arch): Stefan Husmann <stefan-husmann@t-online.de>
# Contributor (Arch): Simon Lipp <sloonz+aur@gmail.com>
# Maintainer: Omar Vega Ramos <ovruni@gnu.org.pe>
pkgname=fop
pkgver=2.7
pkgrel=1.parabola1
pkgdesc='XSL-FO implementation in Java.'
arch=('any')
url='http://xmlgraphics.apache.org/fop/'
license=('APACHE')
depends=('java-xmlgraphics-commons' 'java-commons-logging' 'java-commons-io' 'java-batik'
'java-qdox' 'fontbox' 'tomcat8')
makedepends=('apache-ant' 'jh')
source=("https://dlcdn.apache.org/xmlgraphics/${pkgname}/source/${pkgname}-${pkgver}-src.tar.gz"{,.asc}
'fop.conf')
sha256sums=('b4f1a5212989cebc7d17c7275fbd23de73cc57259d9288c01436556254ad86d4'
'SKIP'
'd2900605dc271f5938d0820ca30bdec8060724976b56e43d827157bd6975da96')
sha512sums=('bffbc0a97db8bbc826cf9af89fbf4a7e6f705585ea4915c0954df57c6d7af50d323387bb4bb9e2d13047826352d9eb7cbf4f23d5146ce246965b4c531e015633'
'SKIP'
'dc180d2c36ef6843405238b41093b80d5b6088828f7e2bb2eb716102d7452d2cc8c6abe5abfd94e4fce9531202440e932250c80debb042a9bb51fa205c1df858')
validpgpkeys=('5C9A30FF22B2C02F30261C305B93F1DF7CDB6DEA') # Simon Steiner
backup=('etc/fop.conf')
prepare() {
cd "$srcdir/$pkgname-$pkgver/fop"
rm -rv lib/*
mkdir -p lib/build
ln -sf /usr/share/java/qdox.jar lib/build/qdox.jar
}
build() {
cd "$srcdir/$pkgname-$pkgver"
ant -f "$pkgname/build.xml" package \
-lib /usr/share/java/commons-io.jar \
-lib /usr/share/java/commons-logging.jar \
-lib /usr/share/java/fontbox.jar \
-lib /usr/share/java/serializer.jar \
-lib /usr/share/java/xml-apis-ext.jar \
-lib /usr/share/java/xmlgraphics-commons.jar \
-lib /usr/share/java/batik/batik-all.jar \
-lib /usr/share/java/batik/batik-libs.jar \
-lib /usr/share/java/tomcat8/servlet-api.jar
}
package() {
cd "$srcdir/$pkgname-$pkgver"
# Install license file
install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE.txt"
# Install documentation
#install -d "$pkgdir/usr/share/doc/$pkgname"
#cp -r build/javadocs "$pkgdir/usr/share/doc/$pkgname"
# Install Maven artifacts
export DESTDIR=$pkgdir
jh mvn-install org.apache.xmlgraphics $pkgname $pkgver \
"$pkgname/pom.xml" \
"$pkgname/build/$pkgname.jar" \
"$pkgname-$pkgver.jar"
ln -s "/usr/share/java/$pkgname-$pkgver.jar" \
"$pkgdir/usr/share/java/$pkgname.jar"
install -d "$pkgdir/usr/share/java/$pkgname"
ln -s "/usr/share/java/$pkgname.jar" \
"$pkgdir/usr/share/java/$pkgname/$pkgname.jar"
install -Dm0644 "../fop.conf" "$pkgdir/etc/fop.conf"
install -Dm0755 "$pkgname/$pkgname" "$pkgdir/usr/bin/$pkgname"
}
|
