blob: 3cf94f70d0978639dd70c03b0702f0d73e6b1019 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
|
# $Id: PKGBUILD 212492 2017-02-15 05:12:21Z bgyorgy $
# Maintainer (Arch): Balló György <ballogyor+arch at gmail dot com>
# Contributor (Arch): Stefano Facchini <stefano.facchini@gmail.com>
# Maintainer: Omar Vega Ramos <ovruni@gnu.org.pe>
# Contributor : Isaac David <isacdaavid@at@isacdaavid@dot@info>
# Contributor: Daniel Milewski <niitotantei@gmail.com>
# Contributor : André Silva <emulatorman@hyperbola.info>
pkgname=gnome-boxes
pkgver=3.26.2
pkgrel=1.parabola1
pkgdesc="Simple GNOME application to access remote or virtual systems, without suggestions (and logos) of nonfree operating systems"
arch=('i686' 'x86_64' 'armv7h')
url="https://wiki.gnome.org/Boxes"
license=('LGPL')
conflicts=(${pkgname}-libre)
replaces=(${pkgname}-libre)
groups=('gnome')
depends=('cdrkit' 'gtk-vnc' 'libarchive' 'libgudev' 'libosinfo' 'libsecret' 'tracker'
'libvirt-glib' 'mtools' 'qemu' 'spice-gtk3' 'libgovirt')
makedepends=('gobject-introspection' 'intltool' 'itstool' 'spice-protocol' 'vala')
source=(https://download.gnome.org/sources/$pkgname/${pkgver::4}/$pkgname-$pkgver.tar.xz)
sha256sums=('d00fc083182963dc1bbdee5e743ceb28ba03fbf5a9ea87c78d29dca5fb5b9210')
prepare() {
cd $pkgname-$pkgver
# remove distro logos
find ./data/osinfo/ -type f -name '*.xml' -exec sed -i '/<os /,/\/os>/ d' {} +
# I'd rather not use Windows as example in user docs
find ./help/ -type f \( -name '*.po' -o -name '*.page' \) -exec \
sed -Ei 's/(Microsoft )?Windows(™)?/Parabola/' {} +
}
build() {
cd $pkgname-$pkgver
./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var --libexecdir=/usr/lib/$pkgname \
--disable-schemas-compile --enable-vala
make
}
package() {
cd $pkgname-$pkgver
make DESTDIR="$pkgdir" install
}
|
