summaryrefslogtreecommitdiff
path: root/libre/gnome-boxes/PKGBUILD
blob: db25972d14ace3bdcafdba87caaa312177176bc5 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
# $Id: PKGBUILD 212492 2017-02-15 05:12:21Z bgyorgy $
# Maintainer (Arch): Balló György <ballogyor+arch at gmail dot com>
# Contributor (Arch): Stefano Facchini <stefano.facchini@gmail.com>
# Maintainer: André Silva <emulatorman@parabola.nu>
# Contributor: Daniel Milewski <niitotantei@gmail.com>

pkgname=gnome-boxes
pkgver=3.22.4
pkgrel=1.parabola1
pkgdesc="Simple GNOME application to access remote or virtual systems, without artwork for non-FSDG compliant distros and operating systems"
arch=('i686' 'x86_64' 'armv7h')
url="https://wiki.gnome.org/Apps/Boxes"
license=('LGPL')
conflicts=(${pkgname}-libre)
replaces=(${pkgname}-libre)
depends=('cdrkit' 'gtk-vnc' 'libarchive' 'libgudev' 'libosinfo' 'libsecret' 'libtracker-sparql'
         'libvirt-glib' 'mtools' 'qemu' 'spice-gtk3')
makedepends=('gobject-introspection' 'intltool' 'itstool' 'spice-protocol' 'vala')
source=(https://download.gnome.org/sources/$pkgname/${pkgver::4}/$pkgname-$pkgver.tar.xz
        libre.patch)
sha256sums=('585a1c292010ebb479cb60e02621d01d450f84cdad82a61b7ce58a0218e1cff2'
            '73ea08076d1e2608e27969fbf3127b5f45a659b2a8a89b04e349b519ce1d07ba')

prepare() {
  cd $pkgname-$pkgver

  patch -Np1 -i "$srcdir/libre.patch"
}

build() {
  cd $pkgname-$pkgver
  ./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var --libexecdir=/usr/lib/$pkgname \
              --disable-schemas-compile
  make
}

package() {
  cd $pkgname-$pkgver
  make DESTDIR="$pkgdir" install
}