summaryrefslogtreecommitdiff
path: root/libre/gnu-ghostscript/PKGBUILD
blob: c7f95283318b8277c86cc55a5f9850a4431020c5 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
# Maintainer: André Silva <andre.paulista@adinet.com.uy>

pkgname=gnu-ghostscript
_pkgver=9.04
pkgver=9.04.1
pkgrel=1
pkgdesc="An interpreter for the PostScript language from FSF"
arch=('i686' 'x86_64')
license=('GPL3')
depends=('libxt' 'libcups' 'fontconfig' 'jasper' 'zlib' 'libpng>=1.5.7' 'libjpeg' 'libtiff>=4.0.0' 'lcms') # 'lcms2' won't get used) # move in libpaper from community?
makedepends=('gtk2' 'gnutls')
optdepends=('texlive-core:      needed for dvipdf'
            'gtk2:              needed for gsx')
conflicts=('ghostscript')
replaces=('ghostscript-lrpng' 'ghostscript')
provides=('ghostscript-lprng' "ghostscript=$pkgver")
url="https://www.gnu.org/software/ghostscript/"
source=(ftp://ftp.gnu.org/gnu/ghostscript/${pkgname}-${pkgver}.tar.xz
	${pkgname}-cups-rgbw.patch
	libtool.patch)
options=('!libtool' '!makeflags')
md5sums=('aba639a5102afbd2ee30c67831692c27'
         '5a78af559d44a7502978fd09f840e3aa'
         '5bd5d4966007b460deed866a30a0b3c8')

build() {
  cd ${srcdir}/${pkgname}-${pkgver}
  
  # fix broken color printing https://bugs.archlinux.org/task/25519
  patch -Np1 -i ${srcdir}/${pkgname}-cups-rgbw.patch

  # fix libtool version
  patch -Np1 -i ${srcdir}/libtool.patch

  # force it to use system-libs
  rm -rf jpeg libpng zlib jasper expat tiff lcms freetype

LIBS=-lfreetype  ./configure --prefix=/usr \
	--enable-dynamic \
	--with-ijs \
	--with-jbig2dec \
	--with-omni \
	--with-x \
	--with-drivers=ALL\
	--with-fontpath=/usr/share/fonts/Type1:/usr/share/fonts \
	--with-install-cups \
	--enable-fontconfig \
	--enable-freetype \
	--without-luratech \
	--disable-compile-inits #--help # needed for linking with system-zlib
  make

  # Build IJS
  cd ${srcdir}/${pkgname}-${pkgver}/ijs
  ./autogen.sh
  ./configure --prefix=/usr --enable-shared --disable-static
  make
}

package() {
  cd ${srcdir}/${pkgname}-${pkgver}
  make DESTDIR=${pkgdir} \
	cups_serverroot=${pkgdir}/etc/cups \
	cups_serverbin=${pkgdir}/usr/lib/cups install soinstall

  # install missing doc files # http://bugs.archlinux.org/task/18023
  install -m 644 ${srcdir}/${pkgname}-${pkgver}/doc/{Ps2ps2.htm,gs-vms.hlp,gsdoc.el,pscet_status.txt} ${pkgdir}/usr/share/ghostscript/$_pkgver/doc/
  
  mkdir -p ${pkgdir}/usr/share/licenses/ghostscript
  install -m644 LICENSE ${pkgdir}/usr/share/licenses/${_pkgname}/

  # remove unwanted localized man-pages
  rm -rf $pkgdir/usr/share/man/[^man1]*

  # install IJS
  cd ${srcdir}/${pkgname}-${pkgver}/ijs
  make DESTDIR=${pkgdir} install
}