summaryrefslogtreecommitdiff
path: root/libre/icecat/PKGBUILD
blob: cc5889c7a91242aa7ebcb5a25cf3dcf7283d3360 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
# Contributor (ConnochaetOS): Henry Jensen <hjensen@connochaetos.org>
# Contributor (Parabola): Luke Shumaker <lukeshu@sbcglobal.net>
# Contributor: Figue <ffigue at gmail>
# Contributor (Parabola): fauno <fauno@kiwwwi.com.ar>
# Contributor (Parabola): vando <facundo@esdebian.org>
# Contributor (Parabola): André Silva <emulatorman@lavabit.com>
# Maintainer (Parabola): Márcio Silva <coadde@lavabit.com>
# Contributor (Arch): Jakub Schmidtke <sjakub@gmail.com>
# Thank you very much to the older contributors:
# Contributor: evr <evanroman at gmail>
# Contributor: Muhammad 'MJ' Jassim <UnbreakableMJ@gmail.com> 

# If you are updating this package, don't forget to update the version number in
# the value for 'browser.dictionaries.download.url' in 'libre.patch'

_pgo=false
pkgname=icecat
pkgver=17.0.1
pkgrel=1
pkgdesc='The GNUzilla web browser, based on Mozilla Firefox. SafeBrowsing and other Google services disabled!'
arch=(i686 x86_64 mips64el)
license=(GPL2 MPL LGPL)
depends=(
  alsa-lib
  dbus-glib
  desktop-file-utils
  gtk2
  hicolor-icon-theme
  hunspell
  libevent
  libnotify
  libvpx
  libxt
  mime-types
  mozilla-common
  mozilla-searchplugins
  'nss>=3.13.3'
  sqlite3
  startup-notification
)
makedepends=(
  autoconf2.13
  diffutils
  imagemagick
  libidl2
  librsvg
  libxslt
  mesa
  pkg-config
  python2
  unzip
  wireless_tools
  zip
)
optdepends=(
  'wireless_tools: Location detection via available WiFi networks'
)
if $_pgo; then
  makedepends+=(xorg-server-xvfb)
  options=(!ccache)
fi
options=(!emptydirs)
url=http://www.gnu.org/software/gnuzilla/
install=$pkgname.install
source=(
  ftp://ftp.gnu.org/gnu/gnuzilla/${pkgver::4}/$pkgname-$pkgver.tar.gz
  mozconfig
  mozconfig.pgo
  xulrunner-copy-stub.patch
  libre.patch
  $pkgname.desktop
  $pkgname-safe.desktop
  $pkgname-install-dir.patch
  vendor.js
  #cairo.patch
)
md5sums=(
  c88a29aa92fc41a07e777a0e63ac5f7e
  a22327391a1995703436ed42fe703d3f
  ac29b01c189f20abae2f3eef1618ffc0
  3009b176cc5f9b1e416b1bf7c45b064b
  f4cffe48e84283026da634424f4bbee6
  e81ad01dbc16ba28bf92ba4b7c309ca7
  d93fe402b87cd000a869e1fd6badc6c9
  64826fcf48816b13090042eefddbaa58
  0d053487907de4376d67d8f499c5502b
  #c8552d030494443218d88792f4dbbd0f
)

build() {
  mv $pkgname-$pkgver $srcdir/gnuzilla-build
  cd $srcdir/gnuzilla-build

  cp $srcdir/mozconfig .mozconfig # Load our build config, disable SafeSearch
  if $_pgo; then
    cat $srcdir/mozconfig.pgo >> .mozconfig
  fi
  patch -Np1 -i $srcdir/$pkgname-install-dir.patch # install to /usr/lib/$pkgname
  patch -Np1 -i $srcdir/xulrunner-copy-stub.patch # small fix
  patch -Np1 -i $srcdir/libre.patch # Remove Google+Mozilla stuff
  #patch -Np1 -i $srcdir/cairo.patch # fix cairo

  # Fix for use nspr, sqlite and nss external
  sed -i 's/\(MOZ_PKG_FATAL_WARNINGS =\).*/\1 0/' \
    browser/installer/Makefile.in

  # Fix PRE_RELEASE_SUFFIX
  sed -i '/^PRE_RELEASE_SUFFIX := ""/s/ ""//' \
    browser/base/Makefile.in

  # This is a bug, we should fix it.
  if [ $CARCH = mips64el ]; then
      # Fix MIPS N32 support.
      sed -i 's/defined(_ABIO32)/(defined(_ABIO32) || defined(_ABIN32))/' \
          js/src/assembler/wtf/Platform.h
      # Disable JIT.
      sed -ri 's/#define ENABLE_(JIT|ASSEMBLER) 1/#define ENABLE_\1 0/' \
          js/src/assembler/wtf/Platform.h
      sed -ri 's/ENABLE_(JIT|ASSEMBLER)=1/ENABLE_\1=0/' js/src/Makefile.in
      echo 'ac_add_options --disable-methodjit' >> .mozconfig
      echo 'ac_add_options --disable-tracejit' >> .mozconfig
      echo 'ac_add_options --disable-jemalloc' >> .mozconfig
  fi

  chmod +x build/unix/run-icecat.sh # fix bug for bad file permition
  export LDFLAGS="$LDFLAGS -Wl,-rpath,/usr/lib/$pkgname"
  export PYTHON=/usr/bin/python2

  if $_pgo; then
    LD_PRELOAD="" /usr/bin/Xvfb -nolisten tcp -extension GLX -screen 0 1280x1024x24 :99 &
    LD_PRELOAD="" DISPLAY=:99 make -j1 -f client.mk profiledbuild MOZ_MAKE_FLAGS=$MAKEFLAGS
    kill $! || true
  else
    LD_PRELOAD="" make -j1 -f client.mk build MOZ_MAKE_FLAGS=$MAKEFLAGS
  fi
}

package() {
  cd $srcdir/gnuzilla-build
  make -j1 -f client.mk DESTDIR=$pkgdir install

  install -Dm644 $srcdir/vendor.js $pkgdir/usr/lib/$pkgname/defaults/pref

  brandingdir=browser/branding/unofficial
  icondir=$pkgdir/usr/share/icons/hicolor
  for i in 16x16 32x32 48x48; do
    install -Dm644 $brandingdir/default${i/x*/}.png $icondir/$i/apps/$pkgname.png
  done

  for d in $pkgname $pkgname-safe; do
    install -Dm644 $srcdir/$d.desktop $pkgdir/usr/share/applications/$d.desktop
  done

  rm -rf $pkgdir/usr/lib/$pkgname/{dictionaries,hyphenation,searchplugins,plugins}
  ln -sf /usr/share/hunspell            $pkgdir/usr/lib/$pkgname/dictionaries
  ln -sf /usr/share/hyphen              $pkgdir/usr/lib/$pkgname/hyphenation
  ln -sf /usr/lib/mozilla/plugins       $pkgdir/usr/lib/$pkgname/plugins
  ln -sf /usr/lib/mozilla/searchplugins $pkgdir/usr/lib/$pkgname/searchplugins

  # We don't want the development stuff
  rm -rf $pkgdir/usr/{include,lib/$pkgname-devel,share/idl}

  # Workaround for now: https://bugzilla.mozilla.org/show_bug.cgi?id=658850
  ln -sf $pkgname $pkgdir/usr/lib/$pkgname/$pkgname-bin
}