blob: 5a112b979e27bd31f61da53ccb25547ba3397973 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
|
# Maintainer (Arch): Guillaume ALAUX <Guillaume at Arch Linux dot org>
# Rationale: Arch version isn't built from source.
# Maintainer: Omar Vega Ramos <ovruni@gnu.org.pe>
pkgname=junit
pkgver=4.12
pkgrel=2.parabola1
pkgdesc='Simple JVM framework to write repeatable tests'
arch=('any')
url='http://www.junit.org/'
license=('EPL')
depends=('java-runtime' 'java-hamcrest')
makedepends=('apache-ant' 'jh')
source=("https://github.com/junit-team/${pkgname}/archive/r${pkgver}.tar.gz"
"build.xml")
sha512sums=('ba612598fa6c328e8f4bbea3afda08b459a110837ca3805a62e811535f7bca8d04509f8fe51a413c7bc855fccee35d6946c9eece4dd01726d12454c002a4de32'
'0ddf2f8ad2b42b427198227be323335eef16a8f189bbff8c8b0a6dc28fea2b6c47c847667f3c745ee696c79f5690424b74be8b0de42e9f89f4b93e403cb679a1')
prepare() {
cd "${srcdir}/${pkgname}4-r${pkgver}"
rm -rv lib/*.jar
mv ../build.xml .
ln -sf /usr/share/java/hamcrest-core.jar lib/hamcrest-core-1.3.jar
}
build() {
cd "${srcdir}/${pkgname}4-r${pkgver}"
ant dist
}
package() {
cd "${srcdir}/${pkgname}4-r${pkgver}"
# Install license file
install -Dm644 LICENSE-junit.txt "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE.txt"
# Install documentation
install -d "${pkgdir}/usr/share/doc/${pkgname}"
cp -r "${pkgname}${pkgver}/javadoc" "${pkgdir}/usr/share/doc/${pkgname}"
export DESTDIR="$pkgdir"
jh mvn-install ${pkgname} ${pkgname} ${pkgver} \
pom.xml \
"${pkgname}${pkgver}/${pkgname}-${pkgver}.jar" \
"${pkgname}.jar"
ln -s "/usr/share/java/${pkgname}.jar" \
"${pkgdir}/usr/share/java/${pkgname}-${pkgver}.jar"
}
|
