summaryrefslogtreecommitdiff
path: root/libre/libosinfo/PKGBUILD
blob: fb7c6821b02c287cb1ab109895729a1e49f8960e (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
# $Id: PKGBUILD 191823 2016-10-10 10:17:01Z bgyorgy $
# Maintainer (Arch): Balló György <ballogyor+arch at gmail dot com>
# Contributor (Arch): Stefano Facchini <stefano.facchini@gmail.com>
# Maintainer: André Silva <emulatorman@hyperbola.info>
# Contributor: Daniel Milewski <niitotantei@gmail.com>

pkgname=libosinfo
pkgver=1.0.0
pkgrel=1.parabola2
pkgdesc="GObject based library API for managing information about operating systems, hypervisors and the (virtual) hardware devices they can support, without non-FSDG compliant distros and operating systems support"
arch=('i686' 'x86_64' 'armv7h')
url="http://libosinfo.org/"
license=('GPL' 'LGPL')
depends=('glib2' 'libxslt' 'osinfo-db')
makedepends=('check' 'gobject-introspection' 'intltool' 'libsoup' 'vala')
conflicts=(${pkgname}-libre)
replaces=(${pkgname}-libre)
options=('!libtool')
source=(https://fedorahosted.org/releases/l/i/$pkgname/$pkgname-$pkgver.tar.gz
        libre.patch)
sha256sums=('f7b425ecde5197d200820eb44401c5033771a5d114bd6390230de768aad0396b'
            '5120733768a39b24a02d19f2c4aa7d8e827dfee1aeefe2e2e6fe48f1ebcf4ce5')

prepare() {
  cd $pkgname-$pkgver

  rm -rv {docs,test/isodata/*}

  patch -Np1 -i ../libre.patch

  cd po
  for file in *.po; do
    intltool-update ${file%.*}
    msgattrib --no-obsolete -o $file $file
  done
}

build() {
  cd $pkgname-$pkgver
  ./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var \
              --with-usb-ids-path=/usr/share/hwdata/usb.ids \
              --with-pci-ids-path=/usr/share/hwdata/pci.ids
  make
}

check() {
  cd $pkgname-$pkgver
  # Fails on test-isodetect
  # make check
}

package() {
  cd $pkgname-$pkgver
  make DESTDIR="$pkgdir" install
}