blob: ae827049716b7c67cc553c121c660a4335e188cf (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
|
# Contributor: aimileus <me at aimileus dot nl>
# Maintainer: Fabio 'Lolix' Loli <lolix at disroot.org>
# Contributor: Sergej Pupykin <pupykin.s+arch@gmail.com>
# Contributor: Andreas Schönfelder <passtschu at freenet dot de>
# Contributor: Denis 'GNUtoo' Carikli <GNUtoo@cyberdimension.org>
pkgname=phoronix-test-suite
pkgver=10.8.3
pkgrel=1
pkgrel+=.par1
pkgdesc="Testing and benchmarking tool with nonfree tests disabled (but still listed with 'phoronix-test-suite list-available-tests')"
arch=(any)
license=(GPL3)
url="http://www.phoronix-test-suite.com/"
depends=('make' 'gzip' 'php' 'sed' 'tar' 'which')
makedepends=('python')
optdepends=('php-gd'
'sqlite3: required when running a Phoromatic server.'
'gcc-fortran: required for universe-cli test suite'
'blas: required for universe-cli test suite'
'lapack: required for universe-cli test suite'
'portaudio: required for universe-cli test suite'
'unzip: required for universe-cli test suite'
'mesa-demos: required for universe-cli test suite'
'openmpi: required for universe-cli test suite')
source=("$pkgname-$pkgver.tar.gz::https://github.com/phoronix-test-suite/phoronix-test-suite/archive/v${pkgver}.tar.gz"
"https://raw.githubusercontent.com/FabioLolix/AUR-artifacts/master/phoronix-test-suite-launcher.patch")
sha256sums=('752012b6e94897f03a219157fe1ba6c4198eb16a5ddf026811b739f1f89cfd9e'
'577326343d0303a59fd469c3f9c9740e756dd59c0660c54363b62d6fd1cee26d')
# This patch comes from Guix at the commit
# 92121b8e9db9541b0fdf0e6e0b17e28e03a01277 ("gnu: Add
# phoronix-test-suite."). It disables tests that include nonfree
# software. I've already bugreported to Guix for tests like linux or
# gnupg which download nonfree software so they should be fixed at
# some point. If new problematic tests are found, since Guix is FSDG
# compliant, it is possible to bugreport there to get them fixed, and
# then to backport the fixed patch to Parabola. As I understand this
# phoronix-test-suite-fsdg.patch is also being upstreamed, so once is
# is upstream, it will be possible to directly send patches to fix
# issues upstream.
#
# Note that with this patch, while the tests are disabled, they still
# show up in phoronix-test-suite list-available-tests, but when trying
# to run them they fail to run.
source+=("phoronix-test-suite-fsdg.patch")
sha256sums+=('SKIP')
options=(!strip)
prepare() {
cd "$srcdir/$pkgname-$pkgver"
# Without that fix, running makepkg twice results in the following
# error:
# ==> Starting prepare()...
# The next patch would create the file delete-nonfree-metadata,
# which already exists! Skipping patch.
# [...]
# ==> ERROR: A failure occurred in prepare().
# Aborting...
rm -f delete-nonfree-metadata
patch -Np1 -i "${srcdir}/phoronix-test-suite-fsdg.patch"
patch -Np1 phoronix-test-suite -i "${srcdir}/phoronix-test-suite-launcher.patch"
}
package() {
cd "$srcdir/$pkgname-$pkgver"
./install-sh $pkgdir/usr --free-software-only
}
|
