summaryrefslogtreecommitdiff
path: root/libre/syslinux/PKGBUILD
blob: b4e9fa35aac6a00a5f33110247de5c3b72d29e64 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
# $Id: PKGBUILD 165555 2012-08-23 18:27:20Z thomas $
# Maintainer: Thomas Bächler <thomas@archlinux.org>
# Maintainer: Tobias Powalowski <tpowa@archlinux.org>
# Maintainer (Parabola): André Silva <emulatorman@lavabit.com>

pkgname=syslinux
pkgver=4.05
pkgrel=7
arch=('i686' 'x86_64')
pkgdesc="Collection of boot loaders that boot from FAT, ext2/3/4 and btrfs filesystems, from CDs and via PXE (Parabola rebranded)"
url="http://syslinux.zytor.com/"
license=('GPL2')
depends=('perl' 'glibc')
optdepends=('perl-passwd-md5:  For md5pass'
            'perl-digest-sha1: For sha1pass'
            'mtools:           For mkdiskimage and syslinux support'
            'gptfdisk:         For GPT support'
            'util-linux:       For isohybrid')
makedepends=('nasm')
backup=('boot/syslinux/syslinux.cfg'
        'boot/syslinux/splash.png')
install=syslinux.install
source=(http://www.kernel.org/pub/linux/utils/boot/syslinux/$pkgname-${pkgver}.tar.bz2
        syslinux-dont-build-dos-windows-targets.patch
        syslinux.cfg
        syslinux-install_update
        avoid-using-ext2_fs.patch
        handle-ctors-dtors-via-init_array-and-fini_array.patch
        splash.png)
md5sums=('82299242418385da1274c9479a778cb2'
         '1528c376e43f0eaccaa80d8ad1bc13b4'
         '8dc2afca3739667e892faf04eb97e7b1'
         '680750f73dc2e587ac567d057d485813'
         '2e2c674a71c0c0bf265d96cfc19ce985'
         'd016d03f15177b1bb534ce3753b2aa9b'
         '0035b6cac6756a384b861eda8d33e4f7')

build() {
  # Do not try to build syslinux with our default LDFLAGS, it will fail
  unset LDFLAGS
  cd "$srcdir"/$pkgname-${pkgver}
  # Do not try to build the Windows or DOS installers
  patch -p1 -i "$srcdir"/syslinux-dont-build-dos-windows-targets.patch
  # fix #30084
  patch -Np1 -i "$srcdir"/avoid-using-ext2_fs.patch
  # fix #31065 (booting breaks with gcc 4.7)
  patch -Np1 -i "$srcdir"/handle-ctors-dtors-via-init_array-and-fini_array.patch
  # Fix FHS manpage path
  sed 's|/usr/man|/usr/share/man|g' -i mk/syslinux.mk
  make installer
  make -C utils
  make -C com32
}

package() {
  cd "$srcdir"/$pkgname-${pkgver}
  make INSTALLROOT="$pkgdir" AUXDIR=/usr/lib/syslinux install

  # Install the default configuration
  install -D -m644 "$srcdir"/syslinux.cfg "$pkgdir"/boot/syslinux/syslinux.cfg
  # Install Parabola splash
  install -D -m644 "$srcdir"/splash.png "$pkgdir"/boot/syslinux/splash.png
  # Install the installation and update script
  # This script is maintained at git://gist.github.com/772138.git
  install -D -m755 "$srcdir"/syslinux-install_update "$pkgdir"/usr/sbin/syslinux-install_update
  # move extlinux binary to /usr/sbin
  mv "$pkgdir"/sbin/extlinux "$pkgdir"/usr/sbin/extlinux
  rmdir "$pkgdir"/sbin
}