summaryrefslogtreecommitdiff
path: root/libre/texlive-core-libre/PKGBUILD
blob: 1e3d5534b591f26d6bede8ffd25ad8e8138fcaa6 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
# Maintainer: Rémy Oudompheng <remy@archlinux.org>
# Maintainer (Parabola): Michał Masłowski <mtjm@mtjm.eu>
# Contributor (Parabola): André Silva <emulatorman@lavabit.com>

pkgname=texlive-core-libre
_pkgname=texlive-core
pkgver=2012.28273
_revnr=${pkgver#2012.}
pkgrel=1
pkgdesc="TeX Live core distribution"
license=('GPL')
arch=(any)
depends=('texlive-bin-libre')
optdepends=(
  'perl:        for many useful tools'
  'ruby:        for old ConTeXT MkII and epspdf'
  'tk:          for texdoctk'
  'python2:     for dviasm'
  'ghostscript: for epstopdf, epspdf and other ConTeXt tools' 
  'psutils:     to manipulate the output of dvips'
  't1utils:     can be useful when installing Type1 fonts'
)
groups=('texlive-most')
conflicts=('tetex' 'texlive-latex3' 'texlive-core')
provides=('tetex' 'texlive-latex3' "texlive-core=$pkgver")
replaces=('tetex' 'texlive-latex3' 'texlive-core')
url='http://tug.org/texlive/'
source=("ftp://ftp.archlinux.org/other/texlive/$_pkgname-$pkgver-src.zip"
        "$_pkgname.maps")
options=(!strip)
install=texlive.install
#backup=(etc/texmf/tex/context/config/cont-usr.tex)
md5sums=('42ce6cf5a7728f2ebb9a1a2bbf9dc4ed'
         '82c03f7226e1df4440f30c89c05ee653')

build() {
   cd "$srcdir"

   # remove nonfree packages
   # MeX licensed packages.
   rm {cc-pl,cs,ec,mex,pl}.tar.xz
   # Public domain, will be relicensed.
   rm context-{account,algorithmic,fixme,games,letter,ruby}.tar.xz
   # No specific free license.
   rm euro-ce.tar.xz
   # Remove them from package list.
   sed -ri '/^(cc-pl|cs|ec|mex|pl|context-(account|algorithmic|fixme|games|letter|ruby)|euro-ce) /d' CONTENTS

   echo -n "   --> extracting all packages... "
   for p in *.tar.xz; do 
     bsdtar -xf $p
   done
   echo "done"
   rm -rf {tlpkg,doc,source,omega} || true
}

package() {
   install -m755 -d $pkgdir/var/lib/texmf/arch/installedpkgs
   sed -i '/^#/d' CONTENTS
   install -m644 CONTENTS $pkgdir/var/lib/texmf/arch/installedpkgs/${_pkgname}_${_revnr}.pkgs
   install -m644 $_pkgname.maps $pkgdir/var/lib/texmf/arch/installedpkgs/
   install -m755 -d $pkgdir/usr/share
   wanteddirs=$(for d in *; do test -d $d && [[ $d != texmf* ]] && echo $d; done) || true
   for dir in $wanteddirs; do
     find $dir -type d -exec install -d -m755 $pkgdir/usr/share/texmf-dist/'{}' \;
     find $dir -type f -exec install -m644 '{}' $pkgdir/usr/share/texmf-dist/'{}' \;
   done
   find texmf-dist -type d -exec install -d -m755 $pkgdir/usr/share/'{}' \;
   find texmf-dist -type f -exec install -m644 '{}' $pkgdir/usr/share/'{}' \;
   if [[ -d $pkgdir/usr/share/texmf-dist/scripts ]]; then
     find $pkgdir/usr/share/texmf-dist/scripts -type f -exec chmod a+x '{}' \;
   fi
   # use python2 for dviasm
   sed -i 's/env python/env python2/' $pkgdir/usr/share/texmf-dist/scripts/dviasm/dviasm.py

   # copy config file to texmf-config
   #mkdir -p $pkgdir/etc/texmf/tex/context/config
   #cp -a $pkgdir/usr/share/texmf-dist/tex/context/config/cont-usr.tex \
   #	  $pkgdir/etc/texmf/tex/context/config/cont-usr.tex
   
   # remove obsolete stuff (we don't provide the omega and aleph binaries anyway)
   rm -f $pkgdir/usr/share/texmf-dist/tex/plain/config/{omega,aleph}.ini
   #sed -i '/cherokee\.map/d; /oinuit\.map/d; /omega\.map/d' \
   #    "${pkgdir}/usr/share/texmf-dist/web2c/updmap.cfg"

   # remove upstream updmap.cfg: it contains too many maps.
   rm "${pkgdir}/usr/share/texmf-dist/web2c/updmap.cfg"
 
   # more cleanup
   rm -rf $pkgdir/usr/share/texmf-dist/scripts/context/stubs/mswin/

    # link programs from /usr/share/texmf-dist/scripts
    _linked_scripts="
accfonts/mkt1font
accfonts/vpl2ovp
accfonts/vpl2vpl
bundledoc/arlatex
bundledoc/bundledoc
context/perl/mptopdf.pl
checkcites/checkcites.lua
ctanify/ctanify
ctanupload/ctanupload.pl
de-macro/de-macro
dviasm/dviasm.py
epstopdf/epstopdf.pl
findhyph/findhyph
fontools/afm2afm
fontools/autoinst
fontools/ot2kpx
fragmaster/fragmaster.pl
installfont/installfont-tl
latex2man/latex2man
latexdiff/latexdiff-vc.pl
latexdiff/latexdiff.pl
latexdiff/latexrevise.pl
latexfileversion/latexfileversion
latexmk/latexmk.pl
luaotfload/mkluatexfontdb.lua
match_parens/match_parens
mf2pt1/mf2pt1.pl
mkjobtexmf/mkjobtexmf.pl
oberdiek/pdfatfi.pl
pdfcrop/pdfcrop.pl
pdfjam/pdf180
pdfjam/pdf270
pdfjam/pdf90
pdfjam/pdfbook
pdfjam/pdfflip
pdfjam/pdfjam
pdfjam/pdfjam-pocketmod
pdfjam/pdfjam-slides3up
pdfjam/pdfjam-slides6up
pdfjam/pdfjoin
pdfjam/pdfnup
pdfjam/pdfpun
pkfix-helper/pkfix-helper
pkfix/pkfix.pl
purifyeps/purifyeps
sty2dtx/sty2dtx.pl
texcount/texcount.pl
texdef/texdef.pl
texdiff/texdiff
texdirflatten/texdirflatten
texloganalyser/texloganalyser
thumbpdf/thumbpdf.pl
typeoutfileinfo/typeoutfileinfo.sh
texliveonfly/texliveonfly.py
"
    install -m755 -d $pkgdir/usr/bin
    for _script in ${_linked_scripts}; do
        _scriptbase=$(basename $_script)
        _scriptbase=${_scriptbase%.*}
        ln -s /usr/share/texmf-dist/scripts/${_script} ${pkgdir}/usr/bin/${_scriptbase}
    done
    ln -s /usr/share/texmf-dist/scripts/listings-ext/listings-ext.sh ${pkgdir}/usr/bin/listings-ext.sh

    # additional symlinks
    ln -s epstopdf ${pkgdir}/usr/bin/repstopdf
    ln -s pdfcrop ${pkgdir}/usr/bin/rpdfcrop
}