summaryrefslogtreecommitdiff
path: root/nonprism/choqok/PKGBUILD
blob: a294609afef728ef3c7c33101661c96a8446bb56 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
# $Id: PKGBUILD 197385 2016-11-29 12:58:20Z arojas $
# Contributor (Arch): Peter Richard Lewis <plewis@aur.archlinux.org>
# Contributor (Arch): Andrea Scarpino <andrea@archlinux.org>
# Contributor (Arch): Emanuele Rossi <newdna1510@yahoo.it>
# Contributor (Arch): Bram Schoenmakers <me@bramschoenmakers.nl>
# Maintainer: Márcio Silva <coadde@parabola.nu>

pkgname=choqok
pkgver=1.6.0
pkgrel=1.nonprism1
pkgdesc="A Pump.io/GNU social client for KDE, without Twitter support"
url='http://choqok.gnufolks.org/'
license=('GPL')
arch=('i686' 'x86_64')
conflicts=(${pkgname}-nonprism)
replaces=(${pkgname}-nonprism)
depends=('qoauth' 'knotifyconfig' 'kcmutils' 'kemoticons' 'kdewebkit' 'hicolor-icon-theme')
makedepends=('extra-cmake-modules' 'telepathy-qt' 'kdoctools' 'python')
optdepends=('telepathy-qt: IMstatus plugin')
source=("http://download.kde.org/stable/${pkgname}/${pkgver%.*}/src/${pkgname}-${pkgver}.tar.xz"{,.sig}
        'nonprism.patch')
md5sums=('f61ff13a748a78bb01433c5419c7cc13'
         'SKIP'
         'f68bf572317277170b397347b928493f')
validpgpkeys=('2C7849767F14C23890B12791918F7DDFFD8D0B6E') # Andrea Scarpino <me@andreascarpino.it>

prepare() {
  mkdir -p build

  cd "${srcdir}/${pkgname}-${pkgver}"
  patch -p1 -i ../nonprism.patch
}

build() {
  cd build
  cmake ../${pkgname}-${pkgver} \
    -DCMAKE_BUILD_TYPE=Release \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DKDE_INSTALL_LIBDIR=lib \
    -DBUILD_TESTING=OFF
  make
}

package() {
  cd build
  make DESTDIR="${pkgdir}" install
}