blob: 3b080551bd3379ed191307eeab5affb5a8d00530 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
|
# $Id: PKGBUILD 290827 2017-03-14 10:00:45Z heftig $
# Contributor (Arch): Ionut Biru <ibiru@archlinux.org>
# Contributor: André Silva <emulatorman@riseup.net>
pkgname=empathy
pkgver=3.12.12+111+g3300c6deb
pkgrel=1.nonprism2
pkgdesc="A GNOME instant messaging client using the Telepathy framework, without geoclue2 support"
url="https://wiki.gnome.org/Apps/Empathy"
arch=(i686 x86_64)
license=(GPL2)
depends=(clutter-gst clutter-gtk folks gcr iso-codes libcanberra libpulse webkit2gtk
telepathy-farstream telepathy-glib telepathy-logger telepathy-mission-control
geocode-glib cheese libchamplain libgudev)
makedepends=(intltool itstool docbook-xsl python gnome-common git)
optdepends=('telepathy-gabble: XMPP/Jabber support'
'telepathy-idle: IRC support'
'telepathy-salut: Link-local XMPP support'
'telepathy-rakia: SIP support'
'telepathy-haze: libpurple support')
groups=(gnome)
_commit=3300c6deb7be1209ca38657c03e15ea729df2ae9 # master
source=("git+https://git.gnome.org/browse/empathy#commit=$_commit"
"git+https://git.gnome.org/browse/telepathy-account-widgets")
sha256sums=('SKIP'
'SKIP')
pkgver() {
cd $pkgname
git describe --tags | sed 's/^EMPATHY_//;s/_/./g;s/-/+/g'
}
prepare() {
cd $pkgname
git submodule init
git config --local submodule.telepathy-account-widgets.url "$srcdir/telepathy-account-widgets"
git submodule update
NOCONFIGURE=1 ./autogen.sh
}
build() {
cd $pkgname
export LANG=en_US.UTF-8 LC_ALL=en_US.UTF-8
./configure --prefix=/usr \
--sysconfdir=/etc \
--libexecdir=/usr/lib/empathy \
--disable-static \
--disable-Werror \
--enable-location=no
sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
make
}
package() {
cd $pkgname
make DESTDIR="$pkgdir" install
}
|
