blob: c1347740bdf3a9c0bd7095f852dee26d35d95e0f (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
|
# Maintainer (Arch): Jan Alexander Steffens (heftig) <jan.steffens@gmail.com>
# Maintainer: André Silva <emulatorman@parabola.nu>
# Contributor: Isaac David <isacdaavid@at@isacdaavid.info>
pkgname=gnome-settings-daemon
pkgver=3.24.2
pkgrel=1.nonprism1
pkgdesc="GNOME Settings Daemon, without geoclue2 support"
url="https://git.gnome.org/browse/gnome-settings-daemon"
arch=(i686 x86_64 armv7h)
license=(GPL)
depends=(dconf gnome-desktop gsettings-desktop-schemas libcanberra-pulse libnotify libsystemd
libwacom pulseaudio pulseaudio-alsa upower librsvg libgweather geocode-glib nss
libgudev gtk3-print-backends libnm)
makedepends=(intltool xf86-input-wacom libxslt docbook-xsl python git gnome-common)
groups=(gnome)
_commit=2ff67385f2b7c7adb0ab438cb41d114235a8e40a # tags/GNOME_SETTINGS_DAEMON_3_24_2^0
source=("git+https://git.gnome.org/browse/gnome-settings-daemon#commit=$_commit"
"git+https://git.gnome.org/browse/libgnome-volume-control"
nonprism.patch)
sha256sums=('SKIP'
'SKIP'
'04217ba23fe3d76b04bdb92059257972ee7511aec6f713d807434f6a10e3d1a5')
pkgver() {
cd $pkgname
git describe --tags | sed 's/^GNOME_SETTINGS_DAEMON_//;s/_/./g;s/-/+/g'
}
prepare() {
cd $pkgname
git submodule init
git config --local submodule."panels/media-keys/gvc".url "$srcdir/libgnome-volume-control"
git submodule update
patch -p1 -i $srcdir/nonprism.patch
NOCONFIGURE=1 ./autogen.sh
}
build() {
cd $pkgname
./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var \
--libexecdir=/usr/lib/$pkgname --disable-static
#https://bugzilla.gnome.org/show_bug.cgi?id=656231
sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
make
}
package() {
cd $pkgname
make DESTDIR="$pkgdir" install
}
|
